Laboratoire ICAR » Plateforme TXM

host *;               # allow access from any host (including localhost)

# users must login with name "anonymous" and explicit "" as password!

user anonymous "";

<?xml version="1.0"?>

<xsl:stylesheet xmlns:edate="http://exslt.org/dates-and-times"

  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tei="http://www.tei-c.org/ns/1.0"

  xmlns:xd="http://www.pnp-software.com/XSLTdoc"

  xmlns:txm="http://textometrie.org/1.0"

  xmlns:xi="http://www.w3.org/2001/XInclude" 

  xmlns:svg="http://www.w3.org/2000/svg" 

  xmlns:math="http://www.w3.org/1998/Math/MathML"

  exclude-result-prefixes="tei edate xd txm xi svg math" version="2.0">

  <xsl:output method="xml" encoding="utf-8" omit-xml-declaration="no" indent="no"/>

  <xd:doc type="stylesheet">

    <xd:short>

      Cette feuille permet de convertir les transcription des 

      Chartes de Fontenay au format XML-TEI du projet Oriflamms.

    </xd:short>

    <xd:detail>

      This stylesheet is free software; you can redistribute it and/or

      modify it under the terms of the GNU Lesser General Public

      License as published by the Free Software Foundation; either

      version 3 of the License, or (at your option) any later version.

      This stylesheet is distributed in the hope that it will be useful,

      but WITHOUT ANY WARRANTY; without even the implied warranty of

      MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU

      Lesser General Public License for more details.

      You should have received a copy of GNU Lesser Public License with

      this stylesheet. If not, see http://www.gnu.org/licenses/lgpl.html

    </xd:detail>

    <xd:author>Alexei Lavrentiev alexei.lavrentev@ens-lyon.fr</xd:author>

    <xd:copyright>2015, CNRS / ICAR (Équipe CACTUS)</xd:copyright>

  </xd:doc>

  <!--<xsl:strip-space elements="*"/>-->

  <xsl:param name="baseMsSiglum">A</xsl:param>

  <xsl:variable name="baseMsPattern"><xsl:value-of select="concat('^#?',$baseMsSiglum,'| #?',$baseMsSiglum)"/></xsl:variable>

  <xsl:template match="*|comment()">

    <!-- Copy the current node -->

    <xsl:copy>

      <!-- Including any attributes it has and any child nodes -->

      <xsl:apply-templates select="@*|node()"/>

    </xsl:copy>

  </xsl:template>

  <xsl:template match="processing-instruction()"/>

  <!-- On supprime les attributs par défaut de la DTD TEI -->

  <xsl:template match="@*">

    <xsl:choose>

      <xsl:when test="matches(name(.),'^(part|instant|anchored|full)$')"/>

      <xsl:otherwise><xsl:copy/></xsl:otherwise>

    </xsl:choose>

  </xsl:template>

<xsl:template match="@facs">

  <xsl:attribute name="facs"><xsl:value-of select="replace(.,'\.tif$','.png','i')"/></xsl:attribute>

</xsl:template>

  <xsl:template match="tei:teiHeader">    

      <xsl:copy>

        <xsl:apply-templates select="@*"/>

        <xsl:apply-templates/>

      </xsl:copy>    

  </xsl:template>

<xsl:template match="tei:revisionDesc">

  <xsl:copy>

  <xsl:apply-templates select="@*"/>

    <change xmlns="http://www.tei-c.org/ns/1.0" when="2007-01-01" who="#DS">Publication du document original</change>

    <!-- information récupérée à partir de /TEI/text[1]/front[1]/titlePage[1]/docDate[1] -->

    <change xmlns="http://www.tei-c.org/ns/1.0" when="{format-date(current-date(),'[Y]-[M01]-[D01]')}" who="#auto">Conversion automatique au format XML-TEI-Oriflamms</change>

  <xsl:apply-templates/>

  </xsl:copy>

</xsl:template>

  <xsl:template match="tei:encodingDesc">

    <xsl:copy>

      <xsl:apply-templates select="@*"/>

      <xsl:apply-templates/>

      <xsl:if test="not(//tei:prefixDef[@ident='ori'])">

        <listPrefixDef xmlns="http://www.tei-c.org/ns/1.0">

          <prefixDef xmlns="http://www.tei-c.org/ns/1.0" ident="ori" 

            matchPattern="([a-z]+)" 

            replacementPattern="oriflamms-annotation-scheme.xml#$1">

            <p>In the context of this project, private URIs with the prefix

              "ori" point to <gi>interp</gi> elements in the project's

              oriflamms-annotation-scheme.xml file.

            </p>

          </prefixDef>

        </listPrefixDef>

      </xsl:if>

    </xsl:copy>

  </xsl:template>

<!-- On restructure le document pour avoir un TEI par charte -->

  <!-- TEI devient teiCorpus -->

  <xsl:template match="tei:TEI">

    <xsl:element name="teiCorpus" xmlns="http://www.tei-c.org/ns/1.0">

      <xsl:apply-templates select="@*"/>

      <xsl:apply-templates/>

    </xsl:element>

  </xsl:template>

  <!-- on supprime l'élément text de niveau 1 et travaille directement sur le niveau 2 (l'élément group intermédiaire disparait)-->

<!--  <xsl:template match="tei:TEI/tei:text">

    <xsl:apply-templates select="descendant::tei:text"/>

  </xsl:template>-->

  <xsl:template match="tei:text[descendant::tei:text]">

<!--    <teiCorpus xmlns="http://www.tei-c.org/ns/1.0">

      <teiHeader xmlns="http://www.tei-c.org/ns/1.0">

        <fileDesc xmlns="http://www.tei-c.org/ns/1.0">

          <titleStmt xmlns="http://www.tei-c.org/ns/1.0">

            <title xmlns="http://www.tei-c.org/ns/1.0">

              <xsl:value-of select="tei:group[1]/tei:head[1]"/>

            </title>            

          </titleStmt>

          <publicationStmt xmlns="http://www.tei-c.org/ns/1.0">

            <p xmlns="http://www.tei-c.org/ns/1.0">See the header of the top level teiCorpus</p>

          </publicationStmt>

          <sourceDesc xmlns="http://www.tei-c.org/ns/1.0">

            <p xmlns="http://www.tei-c.org/ns/1.0">See the header of the top level teiCorpus</p>

          </sourceDesc>

        </fileDesc>

        <profileDesc xmlns="http://www.tei-c.org/ns/1.0">

          <!-\- argument devient profileDesc/abstract -\->

          <xsl:apply-templates select="descendant::tei:argument[1]"/>

        </profileDesc>        

      </teiHeader>

      <xsl:apply-templates/>

    </teiCorpus>-->

    <xsl:apply-templates/>

  </xsl:template>

  <xsl:template match="tei:text[descendant::tei:text]/tei:front">

    <xsl:choose>

      <xsl:when test="descendant::tei:div">

        <TEI xmlns="http://www.tei-c.org/ns/1.0" ana="ori:align-no">

          <teiHeader xmlns="http://www.tei-c.org/ns/1.0">

            <fileDesc xmlns="http://www.tei-c.org/ns/1.0">

              <titleStmt xmlns="http://www.tei-c.org/ns/1.0">

                <title xmlns="http://www.tei-c.org/ns/1.0">

                  <xsl:text>Introduction chercheur</xsl:text>

                </title>

              </titleStmt>

              <publicationStmt xmlns="http://www.tei-c.org/ns/1.0">

                <p xmlns="http://www.tei-c.org/ns/1.0">See the header of the top level teiCorpus</p>

              </publicationStmt>

              <sourceDesc xmlns="http://www.tei-c.org/ns/1.0">

                <p xmlns="http://www.tei-c.org/ns/1.0">See the header of the top level teiCorpus</p>

              </sourceDesc>

            </fileDesc>

          </teiHeader>

          <text xmlns="http://www.tei-c.org/ns/1.0">

            <body xmlns="http://www.tei-c.org/ns/1.0">

              <xsl:apply-templates select="descendant::tei:div"/>

            </body>

          </text>

        </TEI>

      </xsl:when>

      <xsl:otherwise>

        <xsl:comment><xsl:copy-of select="."/></xsl:comment>

      </xsl:otherwise>

    </xsl:choose>

  </xsl:template>

  <xsl:template match="tei:text[descendant::tei:text]/tei:back">

    <xsl:choose>

      <xsl:when test="descendant::tei:div">

        <TEI xmlns="http://www.tei-c.org/ns/1.0" ana="ori:align-no">

          <teiHeader xmlns="http://www.tei-c.org/ns/1.0">

            <fileDesc xmlns="http://www.tei-c.org/ns/1.0">

              <titleStmt xmlns="http://www.tei-c.org/ns/1.0">

                <title xmlns="http://www.tei-c.org/ns/1.0">

                  <xsl:text>Annexes</xsl:text>

                </title>

              </titleStmt>

              <publicationStmt xmlns="http://www.tei-c.org/ns/1.0">

                <p xmlns="http://www.tei-c.org/ns/1.0">See the header of the top level teiCorpus</p>

              </publicationStmt>

              <sourceDesc xmlns="http://www.tei-c.org/ns/1.0">

                <p xmlns="http://www.tei-c.org/ns/1.0">See the header of the top level teiCorpus</p>

              </sourceDesc>

            </fileDesc>

          </teiHeader>

          <text xmlns="http://www.tei-c.org/ns/1.0">

            <body xmlns="http://www.tei-c.org/ns/1.0">

              <xsl:apply-templates select="descendant::tei:div"/>

            </body>

          </text>

        </TEI>

      </xsl:when>

      <xsl:otherwise>

        <xsl:comment><xsl:copy-of select="."/></xsl:comment>

      </xsl:otherwise>

    </xsl:choose>

  </xsl:template>

  <xsl:template match="tei:group[@n='edition']|tei:group[@n='recueil']">

    <xsl:apply-templates/>

  </xsl:template>

  <xsl:template match="tei:group[@n='edition']/ tei:group[@n='introduction']">

    <TEI xmlns="http://www.tei-c.org/ns/1.0">

      <teiHeader xmlns="http://www.tei-c.org/ns/1.0">

        <fileDesc xmlns="http://www.tei-c.org/ns/1.0">

          <titleStmt xmlns="http://www.tei-c.org/ns/1.0">

            <title xmlns="http://www.tei-c.org/ns/1.0">

              <xsl:text>Introduction</xsl:text>

            </title>

          </titleStmt>

          <publicationStmt xmlns="http://www.tei-c.org/ns/1.0">

            <p xmlns="http://www.tei-c.org/ns/1.0">See the header of the top level teiCorpus</p>

          </publicationStmt>

          <sourceDesc xmlns="http://www.tei-c.org/ns/1.0">

            <p xmlns="http://www.tei-c.org/ns/1.0">See the header of the top level teiCorpus</p>

          </sourceDesc>

        </fileDesc>

      </teiHeader>

      <xsl:apply-templates/>

    </TEI>

  </xsl:template>

  <xsl:template match="tei:group[@n='edition']/ tei:group[@n='table']">

    <TEI xmlns="http://www.tei-c.org/ns/1.0" ana="ori:align-no">

      <teiHeader xmlns="http://www.tei-c.org/ns/1.0">

        <fileDesc xmlns="http://www.tei-c.org/ns/1.0">

          <titleStmt xmlns="http://www.tei-c.org/ns/1.0">

            <title xmlns="http://www.tei-c.org/ns/1.0">

              <xsl:text>Table</xsl:text>

            </title>

          </titleStmt>

          <publicationStmt xmlns="http://www.tei-c.org/ns/1.0">

            <p xmlns="http://www.tei-c.org/ns/1.0">See the header of the top level teiCorpus</p>

          </publicationStmt>

          <sourceDesc xmlns="http://www.tei-c.org/ns/1.0">

            <p xmlns="http://www.tei-c.org/ns/1.0">See the header of the top level teiCorpus</p>

          </sourceDesc>

        </fileDesc>

      </teiHeader>

      <text xmlns="http://www.tei-c.org/ns/1.0">

        <xsl:copy-of select="."/>

      </text>

    </TEI>

  </xsl:template>

  <xsl:template match="tei:group[@n='edition']/tei:group[@n='recueil']/tei:text">

    <TEI xmlns="http://www.tei-c.org/ns/1.0">

      <teiHeader xmlns="http://www.tei-c.org/ns/1.0">

        <fileDesc xmlns="http://www.tei-c.org/ns/1.0">

          <titleStmt xmlns="http://www.tei-c.org/ns/1.0">

            <title xmlns="http://www.tei-c.org/ns/1.0">

              <xsl:value-of select="descendant::tei:docTitle[1]"></xsl:value-of>

            </title>

            <xsl:if test="descendant::tei:docAuthor">

              <author xmlns="http://www.tei-c.org/ns/1.0">

                <xsl:value-of select="descendant::tei:docAuthor[1]"></xsl:value-of>

              </author>              

            </xsl:if>

          </titleStmt>

          <publicationStmt xmlns="http://www.tei-c.org/ns/1.0">

            <p xmlns="http://www.tei-c.org/ns/1.0">See the header of the top level teiCorpus</p>

          </publicationStmt>

          <!-- les éléments listWit et listBibl sont placés dans sourceDesc -->

          <sourceDesc xmlns="http://www.tei-c.org/ns/1.0">

            <p xmlns="http://www.tei-c.org/ns/1.0">See the header of the top level teiCorpus</p>

          </sourceDesc>

        </fileDesc>

        <profileDesc xmlns="http://www.tei-c.org/ns/1.0">

          <!-- docDate devient profileDesc/creation/date[@type='documentCreation'] -->

          <creation xmlns="http://www.tei-c.org/ns/1.0"><xsl:apply-templates select="descendant::tei:docDate/tei:date"/></creation>

        </profileDesc>

      </teiHeader>

      <text xmlns="http://www.tei-c.org/ns/1.0">

        <xsl:if test="preceding-sibling::*[1][self::tei:milestone]">

          <xsl:copy-of select="preceding-sibling::tei:milestone[1]"></xsl:copy-of>

        </xsl:if>

        <xsl:apply-templates/>

      </text>

    </TEI>

  </xsl:template>

  <xsl:template match="tei:text[not(descendant::tei:text)]/tei:front">

  </xsl:template>

<xsl:template match="tei:argument"/>

  <xsl:template match="tei:milestone">

    <xsl:choose>

      <xsl:when test="parent::tei:group"/>

      <xsl:otherwise>

        <xsl:copy-of select="."/>

      </xsl:otherwise>

    </xsl:choose>

  </xsl:template>

<xsl:template match="tei:group/tei:head"/>

  <!-- on supprime listWit du corps du texte (cf. l'entête) -->

  <xsl:template match="tei:listWit"/>

<!-- on supprime les entêtes et pied de pages (non alignables) -->

  <xsl:template match="tei:fw">

    <xsl:comment>fw : <xsl:copy-of select="."/></xsl:comment>

  </xsl:template>

  <!-- on ajoute un attribut pour faciliter l'identification des segments à ne pas aligner -->

  <xsl:template match="tei:choice/tei:expan|tei:choice/tei:corr|tei:supplied|tei:note">

    <xsl:copy>

      <xsl:apply-templates select="@*"/>

      <xsl:attribute name="ana">ori:align-no</xsl:attribute>

      <xsl:apply-templates/>

    </xsl:copy>

  </xsl:template>

  <xsl:template match="tei:pb">

    <xsl:variable name="facs">

      <xsl:value-of select="@facs"/>

    </xsl:variable>

    <xsl:if test="//tei:zone[@xml:id=substring-after($facs,'#')] and not(preceding::tei:pb[@facs=$facs])">

      <milestone xmlns="http://www.tei-c.org/ns/1.0" unit="surface">

        <xsl:attribute name="facs">

          <xsl:value-of select="//tei:surface[tei:zone[@xml:id=substring-after($facs,'#')]][1]/tei:graphic/@url"/>

        </xsl:attribute>

      </milestone>

    </xsl:if>

    <xsl:copy-of select="."/>

  </xsl:template>

<xsl:template match="text()[following-sibling::*[1][self::tei:milestone or self::tei:pb or self::tei:cb or self::tei:lb] and following-sibling::tei:lb[1][@break='no']]">

  <xsl:choose>

    <!-- patch d'espace blanc devant les sauts de ligne à l'intérieur de mots -->

    <xsl:when test="matches(.,'\s+$')"><xsl:value-of select="replace(.,'\s+$','')"/></xsl:when>

    <xsl:otherwise><xsl:copy/></xsl:otherwise>

  </xsl:choose>

</xsl:template>

  <xsl:template match="tei:witDetail">

    <xsl:text> </xsl:text>

    <xsl:copy>

      <xsl:apply-templates select="@*"/>

      <xsl:attribute name="ana">ori:align-no</xsl:attribute>

      <xsl:apply-templates/>

    </xsl:copy>

  </xsl:template>

</xsl:stylesheet>

<?xml version="1.0"?>

<xsl:stylesheet xmlns:edate="http://exslt.org/dates-and-times"

  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tei="http://www.tei-c.org/ns/1.0"

  exclude-result-prefixes="tei edate" version="2.0">

  <xsl:output method="xml" encoding="utf-8" omit-xml-declaration="no"/>

	<xsl:template match="node()|@*">

		<!-- Copy the current node -->

		<xsl:copy>

			<!-- Including any attributes it has and any child nodes -->

			<xsl:apply-templates select="@*|node()"/>

		</xsl:copy>

	</xsl:template>

<!--	<xsl:variable name="filename">

		<xsl:analyze-string select="document-uri(.)" regex="^(.*)/([^/]+)\.[^/]+$">

			<xsl:matching-substring>

				<xsl:value-of select="regex-group(2)"/>

			</xsl:matching-substring>

		</xsl:analyze-string>

	</xsl:variable>

	<xsl:variable name="filedir">

		<xsl:analyze-string select="document-uri(.)" regex="^(.*)/([^/]+)\.[^/]+$">

			<xsl:matching-substring>

				<xsl:value-of select="regex-group(1)"/>

			</xsl:matching-substring>

		</xsl:analyze-string>

	</xsl:variable>

	<xsl:variable name="filenameresult">

		<xsl:value-of select="replace($filename,'(-ori)?-w$','')"/>

	</xsl:variable>

	<xsl:variable name="path">

		<xsl:value-of select="concat($filedir,'/',$filenameresult,'-c-temp/?select=*.xml;recurse=yes;on-error=warning')"/>

	</xsl:variable>

	<xsl:variable name="files" select="collection($path)"/>

	<xsl:template match="/">

		<root>Processing files from <xsl:value-of select="$filedir/$filenameresult"/>-c-temp directory. Result files saved in <xsl:value-of select="$filedir/$filenameresult"/>-c directory.</root>

		<xsl:for-each select="$files">

			<xsl:variable name="filename2">

				<xsl:analyze-string select="document-uri(.)" regex="^(.*)/([^/]+).xml$">

					<xsl:matching-substring>

						<xsl:value-of select="regex-group(2)"></xsl:value-of>

					</xsl:matching-substring>

				</xsl:analyze-string></xsl:variable>

			<xsl:result-document href="{$filedir}/{$filenameresult}-c/{$filename2}-c.xml">

				<xsl:apply-templates/>

			</xsl:result-document>

		</xsl:for-each>

	</xsl:template>

-->

<xsl:template match="tei:c">

	<xsl:variable name="w-id">

		<xsl:choose>

			<xsl:when test="ancestor::tei:pc"><xsl:value-of select="ancestor::tei:pc[1]/@xml:id"/></xsl:when>

			<xsl:when test="ancestor::tei:w"><xsl:value-of select="ancestor::tei:w[1]/@xml:id"/></xsl:when>

			<xsl:when test="ancestor::tei:seg[@type='deleted']"><xsl:value-of select="ancestor::tei:seg[@type='deleted'][1]/@xml:id"/></xsl:when>

		</xsl:choose>

	</xsl:variable>

	<xsl:variable name="position"><xsl:number from="tei:w|tei:pc|tei:seg[@type='deleted']" level="any"/></xsl:variable>

	<xsl:copy>

		<xsl:apply-templates select="@*"/>

		<xsl:attribute name="xml:id"><xsl:value-of select="concat('c_',$w-id,'_',$position)"/></xsl:attribute>

		<xsl:apply-templates/>

	</xsl:copy>

</xsl:template>

</xsl:stylesheet>

<?xml version="1.0" encoding="utf-8"?>

<xsl:stylesheet

		xmlns:xsl="http://www.w3.org/1999/XSL/Transform"

		xmlns:xd="http://www.pnp-software.com/XSLTdoc"

		xmlns:tei="http://www.tei-c.org/ns/1.0"

		version="2.0" xpath-default-namespace="http://www.tei-c.org/ns/1.0">

  <xd:doc type="stylesheet">

    <xd:short>

      Cette feuille permet de découper un fichier XML TEI Oriflamms en pages

      avant de procéder à la tokénisation au niveau de caractère.

    </xd:short>

    <xd:detail>

      This software is dual-licensed:

      1. Distributed under a Creative Commons Attribution-ShareAlike 3.0

      Unported License http://creativecommons.org/licenses/by-sa/3.0/ 

      2. http://www.opensource.org/licenses/BSD-2-Clause

      All rights reserved.

      Redistribution and use in source and binary forms, with or without

      modification, are permitted provided that the following conditions are

      met:

      * Redistributions of source code must retain the above copyright

      notice, this list of conditions and the following disclaimer.

      * Redistributions in binary form must reproduce the above copyright

      notice, this list of conditions and the following disclaimer in the

      documentation and/or other materials provided with the distribution.

      This software is provided by the copyright holders and contributors

      "as is" and any express or implied warranties, including, but not

      limited to, the implied warranties of merchantability and fitness for

      a particular purpose are disclaimed. In no event shall the copyright

      holder or contributors be liable for any direct, indirect, incidental,

      special, exemplary, or consequential damages (including, but not

      limited to, procurement of substitute goods or services; loss of use,

      data, or profits; or business interruption) however caused and on any

      theory of liability, whether in contract, strict liability, or tort

      (including negligence or otherwise) arising in any way out of the use

      of this software, even if advised of the possibility of such damage.

      $Id$

      This stylesheet is based on TEI processpb.xsl by Sebastian Rahtz 

      available at 

      https://github.com/TEIC/Stylesheets/blob/master/tools/processpb.xsl 

      and is adapted by Alexei Lavrentiev to split an XML TEI Oriflamms file

      into pages for further tokenizatrion at character level.

    </xd:detail>

    <xd:author>Alexei Lavrentiev alexei.lavrentev@ens-lyon.fr</xd:author>

    <xd:copyright>2015, CNRS / ICAR (Équipe CACTUS)</xd:copyright>

  </xd:doc>

  <xsl:output indent="no" method="xml"/>

  <xsl:variable name="filename">

    <xsl:analyze-string select="document-uri(.)" regex="^(.*)/([^/]+)\.[^/]+$">

      <xsl:matching-substring>

        <xsl:value-of select="regex-group(2)"/>

      </xsl:matching-substring>

    </xsl:analyze-string>

  </xsl:variable>

  <xsl:variable name="filedir">

    <xsl:analyze-string select="document-uri(.)" regex="^(.*)/([^/]+)\.[^/]+$">

      <xsl:matching-substring>

        <xsl:value-of select="regex-group(1)"/>

      </xsl:matching-substring>

    </xsl:analyze-string>

  </xsl:variable>

  <!--<xsl:variable name="filenameresult">

    <xsl:value-of select="replace($filename,'(-ori)?-w$','')"/>

  </xsl:variable>-->

  <xsl:param name="output-directory"><xsl:value-of select="concat($filedir,'/out')"/></xsl:param>

  <xsl:template match="teiHeader">

    <!--<xsl:copy-of select="."/>-->

  </xsl:template>

  <xsl:template match="TEI|teiCorpus|group|text">

    <xsl:copy>

      <xsl:apply-templates select="@*"/>

      <xsl:apply-templates select="*|processing-instruction()|comment()|text()"/>

    </xsl:copy>

  </xsl:template>

  <xsl:template match="text/body|text/back|text/front">

      <xsl:variable name="pages">

	<xsl:copy>

	  <xsl:apply-templates select="@*"/>

	  <xsl:apply-templates

	      select="*|processing-instruction()|comment()|text()"/>

	</xsl:copy>

      </xsl:variable>

      <xsl:for-each select="$pages">

	<xsl:apply-templates  mode="pass2"/>

      </xsl:for-each>

  </xsl:template>

 <!-- first (recursive) pass. look for <pb> elements and group on them -->

  <xsl:template match="comment()|@*|processing-instruction()|text()">

    <xsl:copy-of select="."/>

  </xsl:template>

  <xsl:template match="*">

    <xsl:call-template name="checkpb">

      <xsl:with-param name="eName" select="local-name()"/>

    </xsl:call-template>

  </xsl:template>

  <xsl:template match="milestone[@unit='surface']">

    <xsl:copy-of select="."/>

  </xsl:template>

  <xsl:template name="checkpb">

    <xsl:param name="eName"/>

    <xsl:choose>

      <xsl:when test="not(.//milestone[@unit='surface'])">

        <xsl:copy-of select="."/>

      </xsl:when>

      <xsl:otherwise>

        <xsl:variable name="pass">

	  <xsl:call-template name="groupbypb">

	    <xsl:with-param name="Name" select="$eName"/>

	  </xsl:call-template>

        </xsl:variable>

	<xsl:for-each select="$pass">

	  <xsl:apply-templates/>

	</xsl:for-each>

      </xsl:otherwise>

    </xsl:choose>

  </xsl:template>

  <xsl:template name="groupbypb">

    <xsl:param name="Name"/>

    <xsl:for-each-group select="node()" group-starting-with="milestone[@unit='surface']">

      <xsl:choose>

        <xsl:when test="self::milestone[@unit='surface']">

          <xsl:copy-of select="."/>

          <xsl:element name="{$Name}" namespace="http://www.tei-c.org/ns/1.0">

	    <xsl:attribute name="rend">CONTINUED</xsl:attribute>

            <xsl:apply-templates select="current-group() except ."/>

          </xsl:element>

        </xsl:when>

        <xsl:otherwise>

          <xsl:element name="{$Name}" namespace="http://www.tei-c.org/ns/1.0">

            <xsl:for-each select="..">

              <xsl:copy-of select="@*"/>

              <xsl:apply-templates select="current-group()"/>

            </xsl:for-each>

          </xsl:element>

        </xsl:otherwise>

      </xsl:choose>

    </xsl:for-each-group>

  </xsl:template>

  <!-- second pass. group by <pb> (now all at top level) and wrap groups

       in <page> -->

  <xsl:template match="*" mode="pass2">

    <xsl:copy>

      <xsl:apply-templates select="@*|*|processing-instruction()|comment()|text()" mode="pass2"/>

    </xsl:copy>

  </xsl:template>

  <xsl:template match="comment()|@*|processing-instruction()|text()" mode="pass2">

    <xsl:copy-of select="."/>

  </xsl:template>

  <xsl:template match="*[milestone[@unit='surface']]" mode="pass2" >

    <xsl:copy>

      <xsl:apply-templates select="@*"/>

      <xsl:for-each-group select="*" group-starting-with="milestone[@unit='surface']">

        <xsl:choose>

          <xsl:when test="self::milestone[@unit='surface']">

          	<xsl:comment> Page <xsl:value-of select="@xml:id"/> enregistrée dans <xsl:value-of select="concat($output-directory,'/',$filename,'_',@xml:id,'.xml')"/></xsl:comment>

            <xsl:text>&#xA;</xsl:text>

          	<xsl:result-document href="{$output-directory}/{$filename}_{@xml:id}.xml" indent="yes" exclude-result-prefixes="#all">

          	<TEI xmlns="http://www.tei-c.org/ns/1.0">

          	  <teiHeader>

          	    <fileDesc>

          	      <titleStmt>

          	        <title>Page <xsl:value-of select="@xml:id"/> of <xsl:value-of select="$filename"/> tokenized at character level.</title>

          	      </titleStmt>

          	      <publicationStmt>

          	        <p>Oriflamms project (http://oriflamms.hypotheses.org)</p>

          	      </publicationStmt>

          	      <sourceDesc>

          	        <p>Converted from <xsl:value-of select="$filename"/>.</p>

          	      </sourceDesc>

          	    </fileDesc>

          	    <revisionDesc>

          	      <change when="{current-dateTime()}">File created.</change>

          	    </revisionDesc>

          	  </teiHeader>

          	  <text>

          	    <body>

          	      <xsl:copy-of select="."/>

        	        <xsl:copy-of select="current-group() except ."/>

          	    </body>

          	  </text>

          	</TEI>

          	</xsl:result-document>

          </xsl:when>

          <xsl:otherwise>

            <xsl:copy-of select="current-group()"/>

          </xsl:otherwise>

        </xsl:choose>

      </xsl:for-each-group>

    </xsl:copy>

  </xsl:template>

</xsl:stylesheet>

<?xml version="1.0"?>

<xsl:stylesheet xmlns:edate="http://exslt.org/dates-and-times"

  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tei="http://www.tei-c.org/ns/1.0"

  xmlns:xd="http://www.pnp-software.com/XSLTdoc"

  xmlns:txm="http://textometrie.org/1.0"

  xmlns:xi="http://www.w3.org/2001/XInclude" 

  xmlns:svg="http://www.w3.org/2000/svg" 

  xmlns:math="http://www.w3.org/1998/Math/MathML"

  exclude-result-prefixes="tei edate xd txm xi svg math" version="2.0">

  <xsl:output method="xml" encoding="utf-8" omit-xml-declaration="no" indent="yes"/>

  <xd:doc type="stylesheet">

    <xd:short>

      Cette feuille permet de convertir les transcription des 

      Chartes de Fontenay au format XML-TEI du projet Oriflamms.

    </xd:short>

    <xd:detail>

      This stylesheet is free software; you can redistribute it and/or

      modify it under the terms of the GNU Lesser General Public

      License as published by the Free Software Foundation; either

      version 3 of the License, or (at your option) any later version.

      This stylesheet is distributed in the hope that it will be useful,

      but WITHOUT ANY WARRANTY; without even the implied warranty of

      MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU

      Lesser General Public License for more details.

      You should have received a copy of GNU Lesser Public License with

      this stylesheet. If not, see http://www.gnu.org/licenses/lgpl.html

    </xd:detail>

    <xd:author>Alexei Lavrentiev alexei.lavrentev@ens-lyon.fr</xd:author>

    <xd:copyright>2015, CNRS / ICAR (Équipe CACTUS)</xd:copyright>

  </xd:doc>

  <xsl:strip-space elements="*"/>

  <xsl:param name="baseMsSiglum">A</xsl:param>

  <xsl:variable name="baseMsPattern"><xsl:value-of select="concat('^#?',$baseMsSiglum,'| #?',$baseMsSiglum)"/></xsl:variable>

  <xsl:template match="node()">

    <!-- Copy the current node -->

    <xsl:copy>

      <!-- Including any attributes it has and any child nodes -->

      <xsl:apply-templates select="@*|node()"/>

    </xsl:copy>

  </xsl:template>

  <!-- On supprime les attributs par défaut de la DTD TEI -->

  <xsl:template match="@*">

    <xsl:choose>

      <xsl:when test="matches(name(.),'^(part|instant|anchored|full)$')"/>

      <xsl:otherwise><xsl:copy/></xsl:otherwise>

    </xsl:choose>

  </xsl:template>

  <xsl:template match="@facs">

    <xsl:attribute name="facs">

      <xsl:value-of select="replace(.,'\tif$','.png')"/>

    </xsl:attribute>

  </xsl:template>

  <xsl:template match="tei:teiHeader">    

      <xsl:copy>

        <xsl:apply-templates select="@*"/>

        <xsl:apply-templates/>

      </xsl:copy>    

  </xsl:template>

<xsl:template match="tei:revisionDesc">

  <xsl:copy>

  <xsl:apply-templates select="@*"/>

    <change xmlns="http://www.tei-c.org/ns/1.0" when="2007-01-01" who="#DS">Publication du document original</change>

    <!-- information récupérée à partir de /TEI/text[1]/front[1]/titlePage[1]/docDate[1] -->

    <change xmlns="http://www.tei-c.org/ns/1.0" when="{format-date(current-date(),'[Y]-[M01]-[D01]')}" who="#auto">Conversion automatique au format XML-TEI-Oriflamms</change>

  <xsl:apply-templates/>

  </xsl:copy>

</xsl:template>

  <xsl:template match="tei:encodingDesc">

    <xsl:copy>

      <xsl:apply-templates select="@*"/>

      <xsl:apply-templates/>

      <xsl:if test="not(//tei:prefixDef[@ident='ori'])">

        <listPrefixDef xmlns="http://www.tei-c.org/ns/1.0">

          <prefixDef xmlns="http://www.tei-c.org/ns/1.0" ident="ori" 

            matchPattern="([a-z]+)" 

            replacementPattern="oriflamms-annotation-scheme.xml#$1">

            <p>In the context of this project, private URIs with the prefix

              "ori" point to <gi>interp</gi> elements in the project's

              oriflamms-annotation-scheme.xml file.

            </p>

          </prefixDef>

        </listPrefixDef>

      </xsl:if>

    </xsl:copy>

  </xsl:template>

<!-- On restructure le document pour avoir un TEI par charte -->

  <!-- TEI devient teiCorpus -->

  <xsl:template match="tei:TEI">

    <xsl:element name="teiCorpus" xmlns="http://www.tei-c.org/ns/1.0">

      <xsl:apply-templates select="@*"/>

      <xsl:apply-templates/>

    </xsl:element>

  </xsl:template>

  <!-- on supprime l'élément text de niveau 1 et travaille directement sur le niveau 2 (l'élément group intermédiaire disparait)-->

  <xsl:template match="tei:TEI/tei:text">

    <xsl:apply-templates select="descendant::tei:text"/>

  </xsl:template>

  <xsl:template match="tei:text//tei:text">

    <TEI xmlns="http://www.tei-c.org/ns/1.0">

      <teiHeader xmlns="http://www.tei-c.org/ns/1.0">

        <fileDesc xmlns="http://www.tei-c.org/ns/1.0">

          <titleStmt xmlns="http://www.tei-c.org/ns/1.0">

            <title xmlns="http://www.tei-c.org/ns/1.0"><xsl:text>Acte original </xsl:text>

              <xsl:value-of select="substring-after(preceding-sibling::comment()[contains(.,'acte original')][1],'acte original ')"/></title>

            <author xmlns="http://www.tei-c.org/ns/1.0"><xsl:value-of select="descendant::tei:docAuthor"/></author>

          </titleStmt>

          <publicationStmt xmlns="http://www.tei-c.org/ns/1.0">

            <p xmlns="http://www.tei-c.org/ns/1.0">See the header of the teiCorpus</p>

          </publicationStmt>

          <!-- les éléments listWit et listBibl sont placés dans sourceDesc -->

          <sourceDesc xmlns="http://www.tei-c.org/ns/1.0">

            <xsl:copy-of select="descendant::tei:listWit"/>

            <xsl:copy-of select="descendant::tei:listBibl[1]"></xsl:copy-of>

          </sourceDesc>

        </fileDesc>

        <profileDesc xmlns="http://www.tei-c.org/ns/1.0">

          <!-- docDate devient profileDesc/creation/date[@type='documentCreation'] -->

          <creation xmlns="http://www.tei-c.org/ns/1.0"><xsl:apply-templates select="descendant::tei:docDate"/></creation>

          <!-- argument devient profileDesc/abstract -->

          <xsl:apply-templates select="descendant::tei:argument"/>

        </profileDesc>

      </teiHeader>

      <text xmlns="http://www.tei-c.org/ns/1.0">

        <body xmlns="http://www.tei-c.org/ns/1.0">

          <xsl:apply-templates select="descendant::tei:div1"/>

        </body>

      </text>

    </TEI>

  </xsl:template>

  <xsl:template match="tei:docDate[ancestor::tei:group]">

    <date type="documentCreation" xmlns="http://www.tei-c.org/ns/1.0">

      <xsl:apply-templates select="@*"/>

      <xsl:apply-templates/>

    </date>

  </xsl:template>

  <xsl:template match="tei:argument">

    <abstract xmlns="http://www.tei-c.org/ns/1.0"><xsl:apply-templates/></abstract>

  </xsl:template>

  <!-- patch of the wrong use of @break -->

<xsl:template match="tei:lb[@break='yes']">

  <xsl:copy>

    <xsl:apply-templates select="@*"/>

    <xsl:attribute name="break">no</xsl:attribute>

  </xsl:copy>

</xsl:template>

  <!-- on ajoute un attribut pour faciliter l'identification des segments à ne pas aligner -->

  <xsl:template match="tei:choice/tei:expan|tei:choice/tei:corr">

    <xsl:copy>

      <xsl:apply-templates select="@*"/>

      <xsl:attribute name="ana">ori:align-no</xsl:attribute>

      <xsl:apply-templates/>

    </xsl:copy>

  </xsl:template>

  <xsl:template match="tei:rdg[not(matches(@wit,$baseMsPattern))]">

    <xsl:copy>

      <xsl:apply-templates select="@*"/>

      <xsl:attribute name="ana">ori:align-no</xsl:attribute>

      <xsl:apply-templates/>

    </xsl:copy>

  </xsl:template>

<xsl:template match="text()[following-sibling::*[1][self::tei:milestone or self::tei:pb or self::tei:cb or self::tei:lb] and following-sibling::tei:lb[1][@break]]">

  <xsl:choose>

    <!-- patch d'espace blanc devant les sauts de ligne à l'intérieur de mots -->

    <xsl:when test="matches(.,'\s+$')"><xsl:value-of select="replace(.,'\s+$','')"/></xsl:when>

    <xsl:otherwise><xsl:copy/></xsl:otherwise>

  </xsl:choose>

</xsl:template>

</xsl:stylesheet>

<?xml version="1.0"?>

<xsl:stylesheet xmlns:edate="http://exslt.org/dates-and-times"

  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tei="http://www.tei-c.org/ns/1.0"

  xmlns:xd="http://www.pnp-software.com/XSLTdoc"

  xmlns:txm="http://textometrie.org/1.0"

  xmlns:xi="http://www.w3.org/2001/XInclude" 

  xmlns:svg="http://www.w3.org/2000/svg" 

  xmlns:math="http://www.w3.org/1998/Math/MathML"

  exclude-result-prefixes="tei edate xd txm xi svg math" version="2.0">

  <xsl:output method="xml" encoding="utf-8" omit-xml-declaration="no" indent="no"/>

  <xd:doc type="stylesheet">

    <xd:short>

      Cette feuille permet de convertir la transcription tokénisée des 

      Chartes de Fontenay au format XML-TEI du projet Oriflamms.

    </xd:short>

    <xd:detail>

      This stylesheet is free software; you can redistribute it and/or

      modify it under the terms of the GNU Lesser General Public

      License as published by the Free Software Foundation; either

      version 3 of the License, or (at your option) any later version.

      This stylesheet is distributed in the hope that it will be useful,

      but WITHOUT ANY WARRANTY; without even the implied warranty of

      MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU

      Lesser General Public License for more details.

      You should have received a copy of GNU Lesser Public License with

      this stylesheet. If not, see http://www.gnu.org/licenses/lgpl.html

    </xd:detail>

    <xd:author>Alexei Lavrentiev alexei.lavrentev@ens-lyon.fr</xd:author>

    <xd:copyright>2015, CNRS / ICAR (Équipe CACTUS)</xd:copyright>

  </xd:doc>

  <xsl:variable name="filename">

    <xsl:analyze-string select="document-uri(.)" regex="^(.*)/([^/]+)\.[^/]+$">

      <xsl:matching-substring>

        <xsl:value-of select="regex-group(2)"/>

      </xsl:matching-substring>

    </xsl:analyze-string>

  </xsl:variable>

  <xsl:strip-space elements="*"/>

  <xsl:template match="/">

    <xsl:apply-templates/>

  </xsl:template>

  <xsl:template match="*">

        <xsl:copy>

          <xsl:apply-templates select="@*"/>

          <xsl:apply-templates select="*|processing-instruction()|comment()|text()"/>

        </xsl:copy>

  </xsl:template>

  <xsl:template match="comment()|text()">

    <xsl:copy/>

  </xsl:template>

  <xsl:template match="processing-instruction()"/>

  <!-- On supprime les attributs par défaut de la DTD TEI -->

  <xsl:template match="@*">

    <xsl:choose>

      <xsl:when test="matches(name(.),'^(part|instant|anchored|full)$')"/>

<!--      <xsl:when test="matches(name(.),'rend')">

        <xsl:choose>

          <xsl:when test="matches(.,'^aggl$')"><xsl:attribute name="rend">space-after(none)</xsl:attribute></xsl:when>

          <xsl:otherwise><xsl:copy/></xsl:otherwise>

        </xsl:choose>

      </xsl:when>-->

      <xsl:otherwise><xsl:copy/></xsl:otherwise>

    </xsl:choose>

  </xsl:template>

  <xsl:template match="tei:teiHeader">    

      <xsl:copy>

        <xsl:apply-templates select="@*"/>

        <xsl:apply-templates/>

      </xsl:copy>    

  </xsl:template>

<xsl:template match="tei:revisionDesc">

  <xsl:copy>

  <xsl:apply-templates select="@*"/>

    <change xmlns="http://www.tei-c.org/ns/1.0" when="2007-01-01" who="#DS">Publication du document original</change>

    <!-- information récupérée à partir de /TEI/text[1]/front[1]/titlePage[1]/docDate[1] -->

    <change xmlns="http://www.tei-c.org/ns/1.0" when="{format-date(current-date(),'[Y]-[M01]-[D01]')}" who="#auto">Conversion automatique au format XML-TEI-Oriflamms</change>

  <xsl:apply-templates/>

  </xsl:copy>

</xsl:template>

  <xsl:template match="tei:encodingDesc">

    <xsl:copy>

      <xsl:apply-templates select="@*"/>

      <xsl:apply-templates/>

      <xsl:if test="not(//tei:prefixDef[@ident='ori'])">

        <listPrefixDef xmlns="http://www.tei-c.org/ns/1.0">

          <prefixDef xmlns="http://www.tei-c.org/ns/1.0" ident="ori" 

            matchPattern="([a-z]+)" 

            replacementPattern="oriflamms-annotation-scheme.xml#$1">

            <p>In the context of this project, private URIs with the prefix

              "ori" point to <gi>interp</gi> elements in the project's

              oriflamms-annotation-scheme.xml file.

            </p>

          </prefixDef>

        </listPrefixDef>

      </xsl:if>

    </xsl:copy>

  </xsl:template>

<!-- On restructure le document pour avoir un TEI par charte -->

  <!-- TEI devient teiCorpus -->

  <xsl:template match="tei:TEI">

    <xsl:element name="teiCorpus" xmlns="http://www.tei-c.org/ns/1.0">

      <xsl:apply-templates select="@*"/>

      <xsl:apply-templates select="tei:teiHeader"/>

      <facsimile xmlns="http://www.tei-c.org/ns/1.0"><xsl:apply-templates select="tei:facsimile"/></facsimile>

      <xsl:apply-templates select="tei:text"/>

    </xsl:element>

  </xsl:template>

<xsl:template match="tei:facsimile">

  <xsl:apply-templates/>

</xsl:template>

  <!-- on supprime l'élément text de niveau 1 et travaille directement sur le niveau 2 (l'élément group intermédiaire disparait)-->

  <xsl:template match="tei:TEI/tei:text">

    <xsl:apply-templates select="descendant::tei:text"/>

  </xsl:template>

  <xsl:template match="tei:text//tei:text[descendant::*[matches(@facs,'\S')]]">

    <TEI xmlns="http://www.tei-c.org/ns/1.0">

      <teiHeader xmlns="http://www.tei-c.org/ns/1.0">

        <fileDesc xmlns="http://www.tei-c.org/ns/1.0">

          <titleStmt xmlns="http://www.tei-c.org/ns/1.0">

            <title xmlns="http://www.tei-c.org/ns/1.0"><xsl:text>Acte original </xsl:text>

              <xsl:value-of select="substring-after(preceding-sibling::comment()[contains(.,'acte original')][1],'acte original ')"/></title>

            <author xmlns="http://www.tei-c.org/ns/1.0"><xsl:value-of select="descendant::tei:docAuthor"/></author>

          </titleStmt>

          <publicationStmt xmlns="http://www.tei-c.org/ns/1.0">

            <p xmlns="http://www.tei-c.org/ns/1.0">See the header of the teiCorpus</p>

          </publicationStmt>

          <!-- les éléments listWit et listBibl sont placés dans sourceDesc -->

          <sourceDesc xmlns="http://www.tei-c.org/ns/1.0">

            <xsl:copy-of select="descendant::tei:listWit"/>

            <xsl:copy-of select="descendant::tei:listBibl[1]"></xsl:copy-of>

          </sourceDesc>

        </fileDesc>

        <profileDesc xmlns="http://www.tei-c.org/ns/1.0">

          <!-- docDate devient profileDesc/creation/date[@type='documentCreation'] -->

          <creation xmlns="http://www.tei-c.org/ns/1.0"><xsl:apply-templates select="descendant::tei:docDate"/></creation>

          <!-- argument devient profileDesc/abstract -->

          <xsl:apply-templates select="descendant::tei:argument"/>

        </profileDesc>

      </teiHeader>

      <text xmlns="http://www.tei-c.org/ns/1.0">

        <xsl:apply-templates select="@*"/>

        <body xmlns="http://www.tei-c.org/ns/1.0">

        <xsl:variable name="facsID">

          <xsl:value-of select="replace(descendant::*[@facs[matches(.,'\S+')]][1]/@facs,'^#','')"/>

        </xsl:variable>

          <xsl:if test="not(tei:body//tei:milestone[@unit='surface'])">

            <milestone xmlns="http://www.tei-c.org/ns/1.0" unit="surface">

              <xsl:attribute name="xml:id">

                <xsl:value-of select="concat('surf_',$filename,'_',replace(translate($facsID,' ()','_--'),'\.\w+$',''))"/>

              </xsl:attribute>

              <xsl:attribute name="facs">

                <xsl:choose>

                  <xsl:when test="matches(descendant::*[@facs][1]/@facs,'^#')">

                    <xsl:value-of select="//tei:zone[@xml:id=$facsID]/preceding-sibling::tei:graphic[1]/@url"/>

                  </xsl:when>

                  <xsl:otherwise><xsl:value-of select="$facsID"/></xsl:otherwise>

                </xsl:choose>

              </xsl:attribute>

            </milestone>

          </xsl:if>

          <xsl:if test="not(descendant::tei:pb[@facs]) and not(tei:body//tei:milestone[@unit='surface'])">

          <pb xmlns="http://www.tei-c.org/ns/1.0">

            <xsl:attribute name="facs">

              <xsl:choose>

                <xsl:when test="matches(descendant::*[@facs][1]/@facs,'^#')">

                  <xsl:value-of select="//tei:graphic[following-sibling::tei:zone[@xml:id=$facsID]]/@url"/>

                  <!--<xsl:value-of select="$facsID"/>-->

                </xsl:when>

                <xsl:otherwise><xsl:value-of select="descendant::*[@facs][1]/@facs"/></xsl:otherwise>

              </xsl:choose>

            </xsl:attribute>

          </pb>

        </xsl:if>

          <xsl:apply-templates select="descendant::tei:div1"/>

        </body>

      </text>

    </TEI>

  </xsl:template>

  <xsl:template match="tei:text//tei:text[not(descendant::*[@facs])]">

    <xsl:comment>No facs attribute provided for any element in this text (n="<xsl:value-of select="@n"/>")!</xsl:comment>

    <xsl:comment><xsl:copy-of select="."/></xsl:comment>

  </xsl:template>

  <xsl:template match="tei:docDate[ancestor::tei:group]">

    <date type="documentCreation" xmlns="http://www.tei-c.org/ns/1.0">

      <xsl:apply-templates select="@*"/>

      <xsl:apply-templates/>

    </date>

  </xsl:template>

  <xsl:template match="tei:argument">

    <abstract xmlns="http://www.tei-c.org/ns/1.0"><xsl:apply-templates/></abstract>

  </xsl:template>

  <!-- on ajoute un attribut pour faciliter l'identification des segments à ne pas aligner -->

  <xsl:template match="tei:choice/tei:expan|tei:choice/tei:corr|tei:div1[@type='edition']">

    <xsl:copy>

      <xsl:apply-templates select="@*"/>

      <xsl:attribute name="ana">ori:align-no</xsl:attribute>

      <xsl:apply-templates/>

    </xsl:copy>

  </xsl:template>

</xsl:stylesheet>

<?xml version="1.0"?>

<xsl:stylesheet xmlns:edate="http://exslt.org/dates-and-times"

  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tei="http://www.tei-c.org/ns/1.0"

  xmlns:xd="http://www.pnp-software.com/XSLTdoc"

  xmlns:txm="http://textometrie.org/1.0"

  xmlns:xi="http://www.w3.org/2001/XInclude" 

  xmlns:svg="http://www.w3.org/2000/svg" 

  xmlns:math="http://www.w3.org/1998/Math/MathML"

  exclude-result-prefixes="tei edate xd txm xi svg math" version="2.0">

  <xsl:output method="xml" encoding="utf-8" omit-xml-declaration="no" indent="no"/>

  <xd:doc type="stylesheet">

    <xd:short>

      Cette feuille permet de rajouter les éléments milestone et cb, et les identifiants 

      manquant sur lb

    </xd:short>

    <xd:detail>

      This stylesheet is free software; you can redistribute it and/or

      modify it under the terms of the GNU Lesser General Public

      License as published by the Free Software Foundation; either

      version 3 of the License, or (at your option) any later version.

      This stylesheet is distributed in the hope that it will be useful,

      but WITHOUT ANY WARRANTY; without even the implied warranty of

      MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU

      Lesser General Public License for more details.

      You should have received a copy of GNU Lesser Public License with

      this stylesheet. If not, see http://www.gnu.org/licenses/lgpl.html

    </xd:detail>

    <xd:author>Alexei Lavrentiev alexei.lavrentev@ens-lyon.fr</xd:author>

    <xd:copyright>2015, CNRS / ICAR (Équipe CACTUS)</xd:copyright>

  </xd:doc>

  <!--<xsl:strip-space elements="*"/>-->

  <xsl:variable name="textID">

    <xsl:analyze-string select="document-uri(.)" regex="^(.*)/([^/]+)\.[^/]+$">

      <xsl:matching-substring>

        <xsl:value-of select="regex-group(2)"/>

      </xsl:matching-substring>

    </xsl:analyze-string>

  </xsl:variable>

  <xsl:template match="/">

    <xsl:apply-templates/>

  </xsl:template>

  <xsl:template match="*">

        <xsl:copy>

          <xsl:apply-templates select="@*"/>

          <xsl:apply-templates select="*|processing-instruction()|comment()|text()"/>

        </xsl:copy>

  </xsl:template>

<xsl:template match="processing-instruction()"></xsl:template>

  <xsl:template match="comment()|text()">

    <xsl:copy/>

  </xsl:template>

  <!-- On supprime les attributs par défaut de la DTD TEI -->

  <xsl:template match="@*">

    <xsl:choose>

      <xsl:when test="matches(name(.),'^(part|instant|anchored|full)$')"/>

      <!--      <xsl:when test="matches(name(.),'rend')">

        <xsl:choose>

          <xsl:when test="matches(.,'^aggl$')"><xsl:attribute name="rend">space-after(none)</xsl:attribute></xsl:when>

          <xsl:otherwise><xsl:copy/></xsl:otherwise>

        </xsl:choose>

      </xsl:when>-->

      <xsl:otherwise><xsl:copy/></xsl:otherwise>

    </xsl:choose>

  </xsl:template>

  <xsl:template match="tei:pb[not(ancestor::tei:supplied)]">

    <xsl:variable name="facs"><xsl:value-of select="@facs"/></xsl:variable>

    <xsl:if test="matches(@facs,'\.(tiff?|png|jpg)$','i') and not(preceding-sibling::*[position() lt 3][self::tei:milestone[@unit='surface']]) and not(preceding::tei:pb[@facs=$facs])">

      <milestone xmlns="http://www.tei-c.org/ns/1.0" unit="surface" facs="{@facs}"/>

    </xsl:if>

    <xsl:copy>

      <xsl:apply-templates select="@*"/>

    </xsl:copy>

    <xsl:if test="not(following::*[position() lt 5][self::tei:cb])">

      <xsl:comment>cb added automatically</xsl:comment>

      <cb xmlns="http://www.tei-c.org/ns/1.0"/>

    </xsl:if>

    <xsl:if test="not(following::*[position() lt 5][self::tei:lb or self::tei:cb])">

      <lb xmlns="http://www.tei-c.org/ns/1.0"/>

      <xsl:comment>lb added automatically</xsl:comment>

    </xsl:if>

  </xsl:template>

  <xsl:template match="tei:cb[not(ancestor::tei:supplied)]">

    <xsl:copy>

      <xsl:apply-templates select="@*"/>

    </xsl:copy>

    <xsl:if test="not(following::*[position() lt 5][self::tei:lb])">

      <lb xmlns="http://www.tei-c.org/ns/1.0"/>

    </xsl:if>

  </xsl:template>

  <xsl:template match="tei:lb">

    <xsl:copy>

      <xsl:apply-templates select="@*"/>

      <xsl:if test="matches(@rend,'^(right|center|centre)#')">

        <xsl:attribute name="type">rejet</xsl:attribute>

      </xsl:if>

    </xsl:copy>

  </xsl:template>

  <xsl:template match="tei:milestone[@unit='surface' and @facs=preceding::tei:milestone[@unit='surface']/@facs]">

    <xsl:comment>Doublon éliminé <xsl:value-of select="@xml:id"/></xsl:comment>

  </xsl:template>

</xsl:stylesheet>

<?xml version="1.0"?>

<xsl:stylesheet xmlns:edate="http://exslt.org/dates-and-times"

  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tei="http://www.tei-c.org/ns/1.0"

  xmlns:xd="http://www.pnp-software.com/XSLTdoc"

  xmlns:txm="http://textometrie.org/1.0"

  exclude-result-prefixes="tei edate xd txm" version="2.0">

  <xsl:output method="xml" encoding="utf-8" omit-xml-declaration="no" indent="no"/>

  <xd:doc type="stylesheet">

    <xd:short>

      Cette feuille permet de convertir la transcription compacte de la 

      Queste del saint Graal au format XML-TEI du projet Oriflamms.

    </xd:short>

    <xd:detail>

      This stylesheet is free software; you can redistribute it and/or

      modify it under the terms of the GNU Lesser General Public

      License as published by the Free Software Foundation; either

      version 3 of the License, or (at your option) any later version.

      This stylesheet is distributed in the hope that it will be useful,

      but WITHOUT ANY WARRANTY; without even the implied warranty of

      MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU

      Lesser General Public License for more details.

      You should have received a copy of GNU Lesser Public License with

      this stylesheet. If not, see http://www.gnu.org/licenses/lgpl.html

    </xd:detail>

    <xd:author>Alexei Lavrentiev alexei.lavrentev@ens-lyon.fr</xd:author>

    <xd:copyright>2014, CNRS / ICAR (Équipe CACTUS)</xd:copyright>

  </xd:doc>

  <xsl:template match="/">

    <xsl:apply-templates/>

  </xsl:template>

  <xsl:template match="*">

        <xsl:copy>

          <xsl:apply-templates select="@*"/>

          <xsl:apply-templates select="*|processing-instruction()|comment()|text()"/>

        </xsl:copy>

  </xsl:template>

  <xsl:template match="comment()|text()">

    <xsl:copy/>

  </xsl:template>

  <xsl:template match="processing-instruction()"></xsl:template>

  <!-- On supprime les attributs par défaut de la DTD TEI -->

  <xsl:template match="@*">

    <xsl:choose>

      <xsl:when test="matches(name(.),'^(part|instant|anchored|full)$')"/>

      <xsl:when test="matches(name(.),'rend')">

        <xsl:choose>

          <xsl:when test="matches(.,'^aggl$')"><xsl:attribute name="rend">space-after(none)</xsl:attribute></xsl:when>

          <xsl:otherwise><xsl:copy/></xsl:otherwise>

        </xsl:choose>

      </xsl:when>

      <xsl:otherwise><xsl:copy/></xsl:otherwise>

    </xsl:choose>

  </xsl:template>

  <xsl:template match="tei:teiHeader">    

      <xsl:copy>

        <xsl:apply-templates select="@*"/>

        <xsl:apply-templates/>

      </xsl:copy>    

  </xsl:template>

<xsl:template match="tei:revisionDesc">

  <xsl:copy>

  <xsl:apply-templates select="@*"/>

  <change xmlns="http://www.tei-c.org/ns/1.0" when="{format-date(current-date(),'[Y]-[M01]-[D01]')}" who="#auto">Conversion automatique au format XML-TEI-Oriflamms</change>

  <xsl:apply-templates/>

  </xsl:copy>

</xsl:template>

  <xsl:template match="tei:encodingDesc">

    <xsl:copy>

      <xsl:apply-templates select="@*"/>

      <xsl:apply-templates/>

      <xsl:if test="not(//tei:prefixDef[@ident='ori'])">

        <listPrefixDef xmlns="http://www.tei-c.org/ns/1.0">

          <prefixDef xmlns="http://www.tei-c.org/ns/1.0" ident="ori" 

            matchPattern="([a-z]+)" 

            replacementPattern="oriflamms-annotation-scheme.xml#$1">

            <p>In the context of this project, private URIs with the prefix

              "ori" point to <gi>interp</gi> elements in the project's

              oriflamms-annotation-scheme.xml file.

            </p>

          </prefixDef>

        </listPrefixDef>

      </xsl:if>

    </xsl:copy>

  </xsl:template>

<xsl:template match="tei:cb[@rend='hidden']">

  <xsl:comment>cb factice supprimé</xsl:comment>

</xsl:template>

<xsl:template match="tei:note|tei:supplied[not(descendant::tei:lb)]">

  <xsl:copy>

    <xsl:apply-templates select="@*"/>

    <xsl:attribute name="ana">

      <xsl:if test="@ana"><xsl:value-of select="concat(@ana,' ')"/></xsl:if>

      <xsl:text>ori:align-no</xsl:text>

    </xsl:attribute>

    <xsl:apply-templates/>

  </xsl:copy>

</xsl:template>

  <xsl:template match="tei:supplied[descendant::tei:lb]">

    <xsl:comment>Ajout éditorial supprimé.</xsl:comment>

  </xsl:template>

<!--<xsl:template match="tei:pb[not(preceding-sibling::*[1][self::tei:milestone[@unit='surface']] or ancestor::tei:supplied)]">

  <milestone xmlns="http://www.tei-c.org/ns/1.0" unit="surface" facs="{@facs}"/>

  <xsl:copy>

    <xsl:apply-templates select="@*"/>

  </xsl:copy>

</xsl:template>-->

<xsl:template match="tei:w[matches(@type,'^PON')]">

  <pc xmlns="http://www.tei-c.org/ns/1.0">

    <xsl:apply-templates select="@*"/>

    <xsl:analyze-string select="." regex="^(.*)%(.*)%(.*)$">

      <xsl:matching-substring>

        <xsl:choose>

          <xsl:when test="matches(regex-group(3),'^$')">

            <xsl:attribute name="ana">ori:align-no</xsl:attribute>

            <reg xmlns="http://www.tei-c.org/ns/1.0" ana="ori:align-no"><xsl:value-of select="regex-group(1)"/></reg>

          </xsl:when>

          <xsl:when test="matches(regex-group(1),'^$')">

            <orig xmlns="http://www.tei-c.org/ns/1.0"><xsl:value-of select="regex-group(3)"/></orig>

          </xsl:when>

          <xsl:otherwise>

            <choice xmlns="http://www.tei-c.org/ns/1.0">

              <reg xmlns="http://www.tei-c.org/ns/1.0" ana="ori:align-no"><xsl:value-of select="regex-group(1)"/></reg>

              <orig xmlns="http://www.tei-c.org/ns/1.0"><xsl:value-of select="regex-group(3)"/></orig>

            </choice>

          </xsl:otherwise>

        </xsl:choose>        

      </xsl:matching-substring>

      <xsl:non-matching-substring><xsl:value-of select="."/></xsl:non-matching-substring>

    </xsl:analyze-string>

  </pc>

</xsl:template>

  <xsl:template match="tei:orig">

    <xsl:apply-templates/>

  </xsl:template>

  <xsl:template match="tei:w[not(matches(@type,'^PON'))]//text()|tei:del[not(ancestor::tei:w or descendant::tei:w)]//text()">

    <xsl:choose>

      <xsl:when test="matches(.,'^\s*$')"><xsl:copy/></xsl:when>

      <xsl:otherwise>

        <xsl:analyze-string select="." regex="#?\*[ijuvIJUVí]|#[A-Za-zÀ-ÿſ]|\{{\{{[^}}]+\}}\}}|#?\(\([^)]+\)\).?|_">

          <xsl:matching-substring>

            <xsl:choose>

              <xsl:when test="matches(.,'\(\(')">

                <xsl:analyze-string select="." regex="^#?\(\(([^\)]+)\)\)(.?)$">

                  <xsl:matching-substring>

                    <xsl:variable name="capitalize">

                      <xsl:choose>

                        <xsl:when test="matches(.,'^#') or matches(.,'_#')">yes</xsl:when>

                        <xsl:otherwise>no</xsl:otherwise>

                      </xsl:choose>

                    </xsl:variable>

                    <xsl:variable name="nextLetter"><xsl:value-of select="regex-group(2)"/></xsl:variable>

                    <xsl:variable name="abbrexpan">

                      <xsl:value-of select="replace(regex-group(1),'#','')"/>

                      <!--<xsl:value-of select="regex-group(1)"/>-->

                    </xsl:variable>

                    <xsl:variable name="abbr">

                      <xsl:choose>

                        <xsl:when test="matches($abbrexpan,'_')"><xsl:value-of select="substring-before($abbrexpan,'_')"/></xsl:when>

                        <xsl:when test="matches($abbrexpan,'^#?(.&#x0305;|.&#x0363;|.&#x0364;|.&#x0365;|bn&#x0305;|ch&#x02BC;&#xA75B;|ch&#x0305;&#xA75B;|ch&#xA75B;&#x0305;|gn&#x0363;t|qn&#x0363;t|&#x035B;|&#x1DD1;|&#x204A;|&#x223B;|&#xA76F;|&#xA770;|&#xF153;|&#xF158;|&#xF1C8;)$')">

                          <xsl:value-of select="$abbrexpan"/>

                        </xsl:when>

                        <xsl:otherwise>xxx</xsl:otherwise>

                      </xsl:choose>

                    </xsl:variable>

                    <xsl:variable name="expannocap" as="element()">

                      <expan xmlns="http://www.tei-c.org/ns/1.0">

                        <xsl:choose>

                          <xsl:when test="matches($abbrexpan,'_')">

                            <xsl:analyze-string select="substring-after($abbrexpan,'_')" regex="\[([^\]]+)\]">

                              <xsl:matching-substring>

                                <ex xmlns="http://www.tei-c.org/ns/1.0"><xsl:value-of select="regex-group(1)"/></ex>

                              </xsl:matching-substring>

                              <xsl:non-matching-substring>

                                <xsl:copy/>

                              </xsl:non-matching-substring>

                            </xsl:analyze-string>

                          </xsl:when>

                          <xsl:when test="matches($abbrexpan,'^bn&#x0305;$')">b<ex xmlns="http://www.tei-c.org/ns/1.0">ie</ex>n</xsl:when>

                          <xsl:when test="matches($abbrexpan,'^(ch&#x02BC;&#xA75B;|ch&#x0305;&#xA75B;|ch&#xA75B;&#x0305;)$')">ch<ex xmlns="http://www.tei-c.org/ns/1.0">evalie</ex>r</xsl:when>

                          <xsl:when test="matches($abbrexpan,'gn&#x0363;t')">g<ex xmlns="http://www.tei-c.org/ns/1.0">r</ex><c xmlns="http://www.tei-c.org/ns/1.0" rend="position(combsup)">a</c>nt</xsl:when>

                          <xsl:when test="matches($abbrexpan,'qn&#x0363;t')">q<ex xmlns="http://www.tei-c.org/ns/1.0">u</ex><c xmlns="http://www.tei-c.org/ns/1.0" rend="position(combsup)">a</c>nt</xsl:when>

                          <xsl:when test="matches($abbrexpan,'.&#x0305;$')">

                            <xsl:value-of select="substring($abbrexpan,1,1)"/>

                            <xsl:choose>

                              <xsl:when test="matches($abbrexpan,'^[aeiou]') and matches($nextLetter,'[bmnp]')"><ex xmlns="http://www.tei-c.org/ns/1.0">m</ex></xsl:when>

                              <xsl:when test="matches($abbrexpan,'^[aeiou]')"><ex xmlns="http://www.tei-c.org/ns/1.0">n</ex></xsl:when>

                              <xsl:when test="matches($abbrexpan,'^[q]')"><ex xmlns="http://www.tei-c.org/ns/1.0">ue</ex></xsl:when>

                              <xsl:when test="matches($abbrexpan,'^[p]')"><ex xmlns="http://www.tei-c.org/ns/1.0">re</ex></xsl:when>

                              <xsl:otherwise>‹bar›</xsl:otherwise>

                            </xsl:choose>

                          </xsl:when>

                          <xsl:when test="matches($abbrexpan,'.&#x0363;')">

                            <xsl:value-of select="substring($abbrexpan,1,1)"/>

                            <xsl:choose>

                              <xsl:when test="matches($abbrexpan,'^[Qq]')"><ex xmlns="http://www.tei-c.org/ns/1.0">u</ex></xsl:when>

                              <xsl:otherwise><ex xmlns="http://www.tei-c.org/ns/1.0">r</ex></xsl:otherwise>

                            </xsl:choose>

                            <c xmlns="http://www.tei-c.org/ns/1.0" rend="position(combsup)">a</c>

                          </xsl:when>

                          <xsl:when test="matches($abbrexpan,'.&#x0364;')">

                            <xsl:value-of select="substring($abbrexpan,1,1)"/>