Laboratoire ICAR » Plateforme TXM

<?xml version="1.0"?>

<xsl:stylesheet xmlns:edate="http://exslt.org/dates-and-times"

  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tei="http://www.tei-c.org/ns/1.0"

  xmlns:me="http://www.menota.org/ns/1.0"

  xmlns:bfm="http://bfm.ens-lsh.fr/ns/1.0"

  xmlns:xd="http://www.pnp-software.com/XSLTdoc"

  exclude-result-prefixes="tei edate bfm me" version="2.0">

  <xsl:output method="xml" encoding="utf-8" omit-xml-declaration="no"/>

  <xd:doc type="stylesheet">

    <xd:short>

      Cette feuille XSLT prépare les fichiers au format TEI Oriflamms

      (tokénisés par mot) à l'imppportation dans TXM avec le module XTZ

      (étape 2 "front").

    </xd:short>

    <xd:detail>

      This stylesheet is free software; you can redistribute it and/or

      modify it under the terms of the GNU Lesser General Public

      License as published by the Free Software Foundation; either

      version 3 of the License, or (at your option) any later version.

      This stylesheet is distributed in the hope that it will be useful,

      but WITHOUT ANY WARRANTY; without even the implied warranty of

      MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU

      Lesser General Public License for more details.

      You should have received a copy of GNU Lesser Public License with

      this stylesheet. If not, see http://www.gnu.org/licenses/lgpl.html

    </xd:detail>

    <xd:author>Alexei Lavrentiev alexei.lavrentev@ens-lyon.fr</xd:author>

    <xd:copyright>2016, CNRS / ICAR (Équipe CACTUS)</xd:copyright>

  </xd:doc>

  <xsl:template match="*" mode="#all">

    <xsl:copy>

      <xsl:apply-templates select="*|@*|processing-instruction()|comment()|text()" mode="#current"/>

    </xsl:copy>

  </xsl:template>

  <xsl:template match="comment()|processing-instruction()|text()|@*">

    <xsl:copy>

      <xsl:apply-templates/>

    </xsl:copy>

  </xsl:template>

  <xsl:template match="comment()|processing-instruction()|@*" mode="expan letters-all 

    letters-alignable characters-alignable">

    <xsl:copy>

      <xsl:apply-templates/>

    </xsl:copy>

  </xsl:template>

  <xsl:variable name="filename">

    <xsl:analyze-string select="document-uri(.)" regex="^(.*)/([^/]+)-w\.xml$">

      <xsl:matching-substring>

        <xsl:value-of select="regex-group(2)"/>

      </xsl:matching-substring>

    </xsl:analyze-string>

  </xsl:variable>

<xsl:template match="tei:teiCorpus">

  <TEI xmlns="http://www.tei-c.org/ns/1.0">

    <text>

      <!-- on ajoute des attributs utiles pour la création de partitions et de sous-corpus -->

      <xsl:apply-templates/>

    </text>

  </TEI>

</xsl:template>

<xsl:template match="tei:TEI[ancestor::tei:teiCorpus]">

<xsl:apply-templates/>

</xsl:template>

  <xsl:template match="tei:teiHeader">

    <!--<xsl:copy-of select="."/>-->

  </xsl:template>

  <xsl:template match="tei:text[not(ancestor::tei:teiCorpus)]">

    <xsl:element name="text" namespace="http://www.tei-c.org/ns/1.0">

      <!-- on ajoute des attributs utiles pour la création de partitions et de sous-corpus -->

      <xsl:apply-templates select="@*"/>

     <xsl:apply-templates/> 

    </xsl:element>

  </xsl:template>

  <xsl:template match="tei:text[ancestor::tei:teiCorpus]">

    <div type="text" id="{$filename}-{count(preceding::tei:text) + 1}" xmlns="http://www.tei-c.org/ns/1.0">

      <xsl:apply-templates select="@*|node()"/>

    </div>

  </xsl:template>

<xsl:template match="tei:w[not(tei:seg[@type='wp'])]">

  <xsl:element name="w" namespace="http://www.tei-c.org/ns/1.0">

    <xsl:apply-templates select="@*"/>

    <xsl:attribute name="expan"><xsl:apply-templates mode="expan"/></xsl:attribute>

    <xsl:attribute name="letters-all"><xsl:apply-templates mode="letters-all"/></xsl:attribute>

    <xsl:attribute name="letters-alignable"><xsl:apply-templates mode="letters-alignable"/></xsl:attribute>

    <xsl:attribute name="characters"><xsl:apply-templates mode="characters-alignable"/></xsl:attribute>

    <xsl:attribute name="abbr-n">

      <xsl:value-of select="count(descendant::tei:abbr)"/>

    </xsl:attribute>

    <xsl:attribute name="ref"><xsl:value-of select="concat($filename,', p. ',preceding::tei:pb[1]/@n,', col. ',preceding::tei:cb[1]/@n,', l. ',preceding::tei:lb[1]/@n)"/></xsl:attribute>

    <xsl:apply-templates/>

  </xsl:element>

</xsl:template>

  <xsl:template match="tei:w[tei:seg[@type='wp']]">

    <xsl:element name="w-lb" namespace="http://www.tei-c.org/ns/1.0">

      <xsl:apply-templates select="@*"/>

      <xsl:attribute name="expan"><xsl:apply-templates mode="expan"/></xsl:attribute>

      <xsl:attribute name="letters-all"><xsl:apply-templates mode="letters-all"/></xsl:attribute>

      <xsl:attribute name="letters-alignable"><xsl:apply-templates mode="letters-alignable"/></xsl:attribute>

      <xsl:attribute name="characters"><xsl:apply-templates mode="characters-alignable"/></xsl:attribute>

      <xsl:attribute name="abbr-n">

        <xsl:value-of select="count(descendant::tei:abbr)"/>

      </xsl:attribute>

      <xsl:attribute name="ref"><xsl:value-of select="concat($filename,', p. ',preceding::tei:pb[1]/@n,', col. ',preceding::tei:cb[1]/@n,', l. ',preceding::tei:lb[1]/@n)"/></xsl:attribute>

      <xsl:apply-templates/>

    </xsl:element>

  </xsl:template>

  <xsl:template match="tei:seg[@type='wp']">

    <xsl:element name="w" namespace="http://www.tei-c.org/ns/1.0">

      <xsl:apply-templates select="@*"/>

      <xsl:attribute name="expan"><xsl:apply-templates mode="expan"/></xsl:attribute>

      <xsl:attribute name="letters-all"><xsl:apply-templates mode="letters-all"/></xsl:attribute>

      <xsl:attribute name="letters-alignable"><xsl:apply-templates mode="letters-alignable"/></xsl:attribute>

      <xsl:attribute name="characters"><xsl:apply-templates mode="characters-alignable"/></xsl:attribute>

      <xsl:attribute name="abbr-n">

        <xsl:value-of select="count(descendant::tei:abbr)"/>

      </xsl:attribute>

      <xsl:attribute name="ref"><xsl:value-of select="concat($filename,', p. ',preceding::tei:pb[1]/@n,', col. ',preceding::tei:cb[1]/@n,', l. ',preceding::tei:lb[1]/@n)"/></xsl:attribute>

      <xsl:apply-templates/>

    </xsl:element>

  </xsl:template>

  <xsl:template match="tei:pc[not(child::tei:reg or @ana='ori:align-no')]">

    <xsl:element name="w" namespace="http://www.tei-c.org/ns/1.0">

      <xsl:apply-templates select="@*"/>

      <xsl:attribute name="type">pc</xsl:attribute>

      <xsl:attribute name="expan"><xsl:apply-templates/></xsl:attribute>

      <xsl:attribute name="letters-all"/>

      <xsl:attribute name="letters-alignable"/>

      <xsl:attribute name="characters"><xsl:apply-templates mode="characters-alignable"/></xsl:attribute>

      <xsl:attribute name="abbr-n">

        <xsl:value-of select="0"/>

      </xsl:attribute>

      <xsl:attribute name="ref"><xsl:value-of select="concat($filename,', p. ',preceding::tei:pb[1]/@n,', col. ',preceding::tei:cb[1]/@n,', l. ',preceding::tei:lb[1]/@n)"/></xsl:attribute>

      <xsl:apply-templates/>

    </xsl:element>

  </xsl:template>

  <xsl:template match="tei:pc[child::tei:reg or @ana='ori:align-no']">

    <xsl:comment><xsl:copy-of select="."/></xsl:comment>

  </xsl:template>

  <xsl:template match="tei:choice[tei:abbr]">

    <xsl:apply-templates select="tei:abbr"/>

  </xsl:template>

  <xsl:template match="tei:choice[tei:abbr]" mode="expan">

    <xsl:apply-templates select="tei:expan" mode="#current"/>

  </xsl:template>

  <xsl:template match="tei:choice[tei:abbr]" mode="letters-all">

    <xsl:apply-templates select="tei:expan" mode="#current"/>

  </xsl:template>

  <xsl:template match="tei:choice[tei:abbr]" mode="letters-alignable">

    <xsl:apply-templates select="tei:expan" mode="#current"/>

  </xsl:template>

  <xsl:template match="tei:choice[tei:abbr]" mode="characters-alignable">

    <xsl:apply-templates select="tei:abbr" mode="#current"/>

  </xsl:template>

  <xsl:template match="tei:choice[tei:orig]" mode="#all">

    <xsl:apply-templates select="tei:orig" mode="#current"/>

  </xsl:template>

  <xsl:template match="tei:reg" mode="#all"></xsl:template>

  <xsl:template match="tei:orig" mode="#all">

    <xsl:apply-templates mode="#current"/>

  </xsl:template>

  <xsl:template match="tei:ex" mode="expan">

    <xsl:text>(</xsl:text>

    <xsl:value-of select="."/>

    <xsl:text>)</xsl:text>

  </xsl:template>

  <xsl:template match="tei:ex" mode="letters-all">

    <xsl:value-of select="."/>

  </xsl:template>

  <xsl:template match="tei:ex" mode="letters-alignable"/>

  <xsl:template match="tei:ex" mode="characters-alignable">

    <xsl:choose>

      <xsl:when test="matches(.,'^(cum|com|con)$','i')">&#xA76F;</xsl:when>

      <xsl:when test="matches(.,'^et$','i')">&#x204A;</xsl:when>

      <xsl:when test="matches(.,'^est$','i')">&#x223B;</xsl:when>

      <xsl:when test="matches(.,'^us$','i')">&#xA770;</xsl:when>

      <xsl:otherwise/>

    </xsl:choose>

  </xsl:template>

  <xsl:template match="tei:supplied"></xsl:template>

<xsl:template match="tei:w//text()" mode="letters-alignable characters-alignable">

  <xsl:analyze-string select="." regex="\p{{M}}">

    <xsl:matching-substring/>

    <xsl:non-matching-substring><xsl:value-of select="."/></xsl:non-matching-substring>

  </xsl:analyze-string>

</xsl:template>

</xsl:stylesheet>