Laboratoire ICAR » Plateforme TXM

Unicode True

!include MUI2.nsh

!include nsDialogs.nsh

!include LogicLib.nsh

;general

Name "TXM TXMVERSION"

;!define Version ""

!define Version "-TXMVERSION"

OutFile "../TXM_TXMDATEVERSION_Win64_installer.exe"

InstallDir "$PROGRAMFILES64\TXM${Version}"

RequestExecutionLevel admin

;compression

;SetCompressor /FINAL /SOLID lzma

;SetCompressorDictSize 64

;interface configuration

!define MUI_HEADERIMAGE

!define MUI_HEADERIMAGE_RIGHT

!define MUI_HEADERIMAGE_BITMAP "header.bmp"

!define MUI_HEADERIMAGE_UNBITMAP "header.bmp"

!define MUI_ICON "install.ico"

!define MUI_UNICON "uninstall.ico"

!define MUI_WELCOMEFINISHPAGE_BITMAP "welcome.bmp" ; optional

;Welcome conf

;!define MUI_WELCOMEFINISHPAGE_BITMAP "welcome.bmp" ; optional

!define MUI_WELCOMEPAGE_TITLE $(WelcomeTitleMessage)

!define MUI_WELCOMEPAGE_TEXT $(WelcomeTextMessage)

;Finish conf

!define MUI_FINISHPAGE_TITLE $(FinishTitleMessage)

!define MUI_FINISHPAGE_TEXT $(FinishTextMessage)

;pages

!insertmacro MUI_PAGE_WELCOME

;!insertmacro MUI_PAGE_LICENSE "license_agreement.txt"

!insertmacro MUI_PAGE_DIRECTORY

Page Custom MyCustomPage MyCustomLeave

Var Dialog

Var Checkbox1

Var CheckState1 ; Stored globally so we remember the choice if the user presses the back button and goes back to our page

Var Checkbox2

Var CheckState2 ; Stored globally so we remember the choice if the user presses the back button and goes back to our page

Function MyCustomPage

	!insertmacro MUI_HEADER_TEXT $(AdvancedOptionsTitle) $(AdvancedOptionsSubTitle)

	nsDialogs::Create 1018

	Pop $Dialog

	${If} $Dialog == error

		Abort

	${EndIf}

	${NSD_CreateCheckBox} 0 0 100% 30% $(LocalInstallMessage)

	Pop $Checkbox1

;	${NSD_Check} $Checkbox1

	${NSD_CreateCheckBox} 0 30% 100% 30% $(AskUserDirMessage)

	Pop $Checkbox2

;	${NSD_Check} $Checkbox2

	nsDialogs::Show

FunctionEnd

Function MyCustomLeave

  ${NSD_GetState} $Checkbox1 $CheckState1

  ${If} $CheckState1 <> 0

    file ROAMINGINSTALL

  ${EndIf}

  ${NSD_GetState} $Checkbox2 $CheckState2

  ${If} $CheckState2 <> 0

    file ASKUSERDIRECTORY

  ${EndIf}

FunctionEnd

!insertmacro MUI_PAGE_INSTFILES

!insertmacro MUI_UNPAGE_CONFIRM

!insertmacro MUI_UNPAGE_INSTFILES

!insertmacro MUI_PAGE_FINISH

;Languages

!insertmacro MUI_LANGUAGE "English"

!insertmacro MUI_LANGUAGE "French"

!insertmacro MUI_LANGUAGE "Russian"

;Lang Strings ENGLISH

LangString AdvancedOptionsTitle ${LANG_ENGLISH} "Advanced options"

LangString AdvancedOptionsSubTitle ${LANG_ENGLISH} "Check these options only for specific Windows configurations"

LangString LocalInstallMessage ${LANG_ENGLISH} "Do not use local user directory (check this option to use a roaming Windows account home directory)."

LangString AskUserDirMessage ${LANG_ENGLISH} "Do not use the user directory to store the TXM working directory (check this option to store corpora on a USB stick or on a remote directory. In this case, the working directory path will be asked at each TXM launch)."

LangString InfosTitleMessage ${LANG_ENGLISH} "For your information"

LangString InfosTextMessage ${LANG_ENGLISH} "If TXM is already installed on this machine, it will first be removed by this installer (TXM corpora will NOT be removed).$\nClose the window to cancel installation.$\n$\nMinimum requirements: Windows 7 64bit"

LangString WelcomeTitleMessage ${LANG_ENGLISH} "Welcome to TXM setup"

LangString WelcomeTextMessage ${LANG_ENGLISH} "TXM is provided to you free of charge. In return, in the spirit of open-source software development, you are invited to participate in its improvement. To do this, you don't have to be a software developer, you can:$\n * send us your publications or course materials related to your use of TXM;$\n * suggest corrections or improvements;$\n * translate in your language the interface or documentation;$\n * Setup a research project involving TXM adaptation and use;$\n * etc.$\n$\n See the 'Contribute' page on the TXM users' wiki: https://groupes.renater.fr/wiki/txm-users/public/contribuer $\n$\n Don't hesitate to contact us for more information at 'textometrie AT groupes.renater DOT fr'."

LangString FinishTitleMessage ${LANG_ENGLISH} "Installation done"

LangString FinishTextMessage ${LANG_ENGLISH} "The installation is done. A 'TXM' entry has been added to the 'Start' menu.$\nIf you want to automatically tag and lemmatize your corpora with the TreeTagger software during import, you need to follow additional installation instructions given in the 'Help > Install TreeTagger' menu."

LangString ErrorArch32Message ${LANG_ENGLISH} "This setup is for 32bit systems but your system seems to be 64bit. Please download and install the 64bit version of TXM for this machine. Continue to install anyway?"

LangString ErrorArch64Message ${LANG_ENGLISH} "This setup is for 64bit systems but your system seems to be 32bit. Please download and install the 32bit version of TXM for this machine. Continue to install anyway?"

LangString UninstallWindowsMessage ${LANG_ENGLISH} "TXM TXMVERSION is already installed on this machine.$\n$\nClick `OK` to uninstall the previous version first (TXM TXMVERSION corpora will NOT be removed).$\nOr click `Cancel` to abort this installation.$\nPlease ensure that no TXM TXMVERSION is running during the installation process."

;Lang Strings FRENCH

LangString AdvancedOptionsTitle ${LANG_FRENCH} "Options avanc?es"

LangString AdvancedOptionsSubTitle ${LANG_FRENCH} "Ne cocher ces options que pour des configurations Windows particuli?res"

LangString LocalInstallMessage ${LANG_FRENCH} "Ne pas utiliser le r?pertoire utilisateur local (cocher cette option si vous souhaitez utiliser un r?pertoire de connexion de compte itin?rant)."

LangString AskUserDirMessage ${LANG_FRENCH} "Ne pas utiliser le r?pertoire utilisateur comme r?pertoire de travail de TXM (cocher cette option pour stocker les corpus sur une cl? USB ou sur un disque distant. Dans ce cas, le chemin du r?pertoire de travail sera demand? chaque lancement de TXM)."

LangString InfosTitleMessage ${LANG_FRENCH} "Pour votre information"

LangString InfosTextMessage ${LANG_FRENCH} "Si TXM est d?j? install? sur cette machine, cet installeur le supprimera pour commencer (les corpus existants ne seront pas supprim?s). Pour annuler l'installation, vous pouvez fermer cette fen?tre.$\n$\nConfiguration minimum: Windows Vista 64bit"

LangString WelcomeTitleMessage ${LANG_FRENCH} "Bienvenue dans l'installeur de TXM"

LangString WelcomeTextMessage ${LANG_FRENCH} "TXM vous est fourni gracieusement. En contre-partie, dans l'esprit du logiciel libre, vous ?tes invit? ? participer ? son am?lioration. Pour cela, vous n'?tes pas oblig? d'?tre d?veloppeur informatique, vous pouvez :$\n * transmettre vos publications ou supports de cours ;$\n * proposer des corrections ou am?liorations ;$\n *  traduire l'interface ou la documentation ;$\n * monter un projet pour adapter TXM ? vos besoins ;$\n * etc.$\n$\n Voir la rubrique 'Contribuer' du wiki des utilisateurs de TXM : https://groupes.renater.fr/wiki/txm-users/public/contribuer $\n$\n N'h?sitez pas ? nous contacter pour de plus amples informations : 'textometrie AT groupes.renater DOT fr'."

LangString FinishTitleMessage ${LANG_FRENCH} "Installation termin?e."

LangString FinishTextMessage ${LANG_FRENCH} "L'installation s'est correctement termin?e. Une entr?e 'TXM' a ?t? ajout?e au menu D?marrer.$\n$\nSi vous souhaitez ?tiqueter et lemmatiser automatiquement vos corpus avec le logiciel TreeTagger lors de l'import, vous devez suivre les instructions d'installation suppl?mentaires fournies dans le menu 'Aide > Installer TreeTagger'."

LangString ErrorArch32Message ${LANG_FRENCH} "La version de TXM que vous allez installer est pour un syst?me 32 bits, or votre syst?me semble ?tre 64 bits. Il faudrait t?l?charger et installer la version 64 bits de TXM. Voulez-vous malgr? tout continuer cette installation ?"

LangString ErrorArch64Message ${LANG_FRENCH} "La version de TXM que vous allez installer est pour un syst?me 64 bits, or votre syst?me semble ?tre 32 bits. Il faudrait t?l?charger et installer la version 32 bits de TXM. Voulez-vous malgr? tout continuer cette installation ?"

LangString UninstallWindowsMessage ${LANG_FRENCH} "TXM TXMVERSION est d?j? install? sur cette machine. Veuillez cliquer sur 'OK' pour d?sinstaller cette version au pr?alable (les corpus seront conserv?s). Ou cliquez sur 'Annuler' pour interrompre l'installation. Merci de vous assurer que TXM TXMVERSION n'est pas en cours d'ex?cution pendant l'installation."

;END OF LANG MESSAGES

Function .onInit

	;!insertmacro MUI_LANGDLL_DISPLAY

	setOutPath $INSTDIR

		ReadRegStr $R0 HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\TXM${Version}" "UninstallString"

		StrCmp $R0 "" done

		MessageBox MB_OKCANCEL|MB_ICONEXCLAMATION $(UninstallWindowsMessage) IDOK uninst

		Abort

	;Run the uninstaller

	uninst:

		ClearErrors

		ExecWait '$R0 _?=$INSTDIR' ;Do not copy the uninstaller to a temp file

		IfErrors no_remove_uninstaller done

		no_remove_uninstaller:

	done:

FunctionEnd

Section "Copy files" SecFiles

	#we install txm in INSTDIR

	SetOutPath $INSTDIR

File /r configuration

File /r doc

File /r features

File /r jre

File /r p2

File /r plugins

File /r readme

File /r redist

File /r samples

File artifacts.xml

File cqpjni.dll

File header.bmp

File IEShims.dll

File install.ico

File libcharset-1.dll

File libglib-2.0-0.dll

File libgnurx-0.dll

File libiconv-2.dll

File libintl-8.dll

File libpcre-1.dll

File LICENSE.TXT

File license_agreement.txt

File license_agreement_fr.txt

File LICENSE_FR.TXT

File OpenAppDataDirectory.bat

File pcre3.dll

File StartDialog.jar

File TXM.bat

File launcher.exe

File TXM.ico

File launcher.ini

File "TXM debug.bat"

File uninstall.ico

	# hide TXM.exe

	SetFileAttributes "$INSTDIR/TXM.exe" HIDDEN

	# the users right on install dir to enable updates

	AccessControl::GrantOnFile "$INSTDIR\TXM" "(S-1-5-32-545)" "FullAccess"

	#we set the shortcuts

	SetShellVarContext all

	CreateDirectory "$SMPROGRAMS\TXM${Version}"

	CreateShortCut "$SMPROGRAMS\TXM${Version}\TXM${Version}.lnk" "$INSTDIR\TXM.bat" "" "$INSTDIR\TXM.ico" 0

	CreateShortCut "$SMPROGRAMS\TXM${Version}\TXM${Version} debug.lnk" "$INSTDIR\TXM debug.bat" "" "$INSTDIR\TXM.ico" 0

	CreateShortCut "$SMPROGRAMS\TXM${Version}\uninstall TXM${Version}.lnk" "$INSTDIR\uninstall.exe"

	#CreateShortCut "$SMPROGRAMS\TXM${Version}\Manuel utilisateur FR.pdf.lnk" "$INSTDIR\doc\Manuel de TXM 0.7 FR.pdf"

	#CreateShortCut "$SMPROGRAMS\TXM${Version}\User Manual EN.pdf.lnk" "$INSTDIR\doc\TXM 0.7 Manual EN.pdf"

	; Store installation folder

	WriteRegStr HKCU "Software\TXM${Version}" "" $INSTDIR

	#register the TXM uninstall to windows programs

	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\TXM${Version}" "UninstallString" "$\"$INSTDIR\uninstall.exe$\""

	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\TXM${Version}" "DisplayName" "TXM${Version}  - The Textometrie project builds the new generation of modular and open-source textometry platform and application. The scientific project web site is http://textometrie.ens-lsh.fr/?lang=en. "

	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\TXM${Version}" "QuietUninstallString" "$\"$INSTDIR\uninstall.exe$\" /S"

	#we create the uninstaller

	WriteUninstaller "$INSTDIR\uninstall.exe"

SectionEnd

Function WriteToFile

	Exch $0 ;file to write to

	Exch

	Exch $1 ;text to write

	FileOpen $0 $0 a #open file

	FileSeek $0 0 END #go to end

	FileWrite $0 $1 #write to file

	FileClose $0

	Pop $1

	Pop $0

FunctionEnd

### TimeStamp

!ifndef TimeStamp

    !define TimeStamp "!insertmacro _TimeStamp"

    !macro _TimeStamp FormatedString

        !ifdef __UNINSTALL__

            Call un.__TimeStamp

        !else

            Call __TimeStamp

        !endif

        Pop ${FormatedString}

    !macroend

!macro __TimeStamp UN

Function ${UN}__TimeStamp

    ClearErrors

    ## Store the needed Registers on the stack

        Push $0 ; Stack $0

        Push $1 ; Stack $1 $0

        Push $2 ; Stack $2 $1 $0

        Push $3 ; Stack $3 $2 $1 $0

        Push $4 ; Stack $4 $3 $2 $1 $0

        Push $5 ; Stack $5 $4 $3 $2 $1 $0

        Push $6 ; Stack $6 $5 $4 $3 $2 $1 $0

        Push $7 ; Stack $7 $6 $5 $4 $3 $2 $1 $0

        ;Push $8 ; Stack $8 $7 $6 $5 $4 $3 $2 $1 $0

    ## Call System API to get the current system Time

        System::Alloc 16

        Pop $0

        System::Call 'kernel32::GetLocalTime(i) i(r0)'

        System::Call '*$0(&i2, &i2, &i2, &i2, &i2, &i2, &i2, &i2)i (.r1, .r2, n, .r3, .r4, .r5, .r6, .r7)'

        System::Free $0

        IntFmt $2 "%02i" $2

        IntFmt $3 "%02i" $3

        IntFmt $4 "%02i" $4

        IntFmt $5 "%02i" $5

        IntFmt $6 "%02i" $6

    ## Generate Timestamp

        ;StrCpy $0 "YEAR=$1$\nMONTH=$2$\nDAY=$3$\nHOUR=$4$\nMINUITES=$5$\nSECONDS=$6$\nMS$7"

        StrCpy $0 "$1$2$3$4$5$6.$7"

    ## Restore the Registers and add Timestamp to the Stack

        ;Pop $8  ; Stack $7 $6 $5 $4 $3 $2 $1 $0

        Pop $7  ; Stack $6 $5 $4 $3 $2 $1 $0

        Pop $6  ; Stack $5 $4 $3 $2 $1 $0

        Pop $5  ; Stack $4 $3 $2 $1 $0

        Pop $4  ; Stack $3 $2 $1 $0

        Pop $3  ; Stack $2 $1 $0

        Pop $2  ; Stack $1 $0

        Pop $1  ; Stack $0

        Exch $0 ; Stack ${TimeStamp}

FunctionEnd

!macroend

!insertmacro __TimeStamp ""

!insertmacro __TimeStamp "un."

!endif

###########

Section "WriteInstallStamp" secStamp

	${TimeStamp} $0

	Push "$0"

	Push "$INSTDIR\STAMP" ;file to write to

	Call WriteToFile

SectionEnd

Section "WriteInstallPrefs" secPrefs

	#we set the default preferences

	;!define pathToCqp "$INSTDIR\cwb\bin\win32\cqpserver.exe"

	;!define pathToCqpLib "$INSTDIR\cwb\bin\"

	;!define pathToInit "$INSTDIR\cwb\cqpserver.init"

	;!define pathToR "$INSTDIR\R\bin\x64\Rterm.exe"

	;!define pathToTT "$PROGRAMFILES\treetagger"

	;!define pathToTTMod "$PROGRAMFILES\treetagger\models"

	;FileOpen $4 "$INSTDIR\install.prefs" a

	;FileSeek $4 0 END

	;FileWrite $4 "$\r$\ncqi_server_path_to_cqplib=${pathToCqpLib}"

	;FileWrite $4 "$\r$\ncqi_server_path_to_executable=${pathToCqp}"

	;FileWrite $4 "$\r$\ncqi_server_path_to_init_file=${pathToInit}"

	;FileWrite $4 "$\r$\nr_path_to_executable=${pathToR}"

	;FileWrite $4 "$\r$\ntreetagger_install_path=${pathToTT}"

	;FileWrite $4 "$\r$\ntreetagger_models_path=${pathToTTMod}"

	;FileClose $4 ; and close the file

SectionEnd

;UninstallText "This will uninstall TXM"

;uninstaller section start

Section "Uninstall"

	SetShellVarContext all

	# Delete installation key

	DeleteRegKey /ifempty HKCU "Software\TXM${Version}"

	# Delete uninstaller key

	DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\TXM${Version}"

	# we remove the software

	RMDir /r $INSTDIR

	RMDir /r "$SMPROGRAMS\TXM${Version}"

SectionEnd