Statistics
| Revision:

root / tmp / org.txm.oriflamms.rcp / groovy / org / txm / macro / oriflamms / prepare / oriflamms-convert-psautiers-oriflammsxml.xsl @ 2398

History | View | Annotate | Download (7.4 kB)

1
<?xml version="1.0"?>
2
<xsl:stylesheet
3
	xmlns:edate="http://exslt.org/dates-and-times"
4
	xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
5
	xmlns:tei="http://www.tei-c.org/ns/1.0"
6
	xmlns:xd="http://www.pnp-software.com/XSLTdoc"
7
	xmlns:txm="http://textometrie.org/1.0"
8
	xmlns:xi="http://www.w3.org/2001/XInclude"
9
	xmlns:svg="http://www.w3.org/2000/svg"
10
	xmlns:math="http://www.w3.org/1998/Math/MathML"
11
	exclude-result-prefixes="tei edate xd txm xi svg math" version="2.0">
12

    
13
	<xsl:output method="xml" encoding="utf-8"
14
		omit-xml-declaration="no" indent="no" />
15

    
16
	<xd:doc type="stylesheet">
17
		<xd:short>
18
			Cette feuille permet de convertir les transcription des
19
			Psautiers au format XML-TEI du projet Oriflamms.
20
		</xd:short>
21
		<xd:detail>
22
			This stylesheet is free software; you can redistribute it and/or
23
			modify it under the terms of the GNU Lesser General Public
24
			License as published by the Free Software Foundation; either
25
			version 3 of the License, or (at your option) any later version.
26

    
27
			This stylesheet is distributed in the hope that it will be useful,
28
			but WITHOUT ANY WARRANTY; without even the implied warranty of
29
			MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
30
			Lesser General Public License for more details.
31

    
32
			You should have received a copy of GNU Lesser Public License with
33
			this stylesheet. If not, see http://www.gnu.org/licenses/lgpl.html
34
		</xd:detail>
35
		<xd:author>Alexei Lavrentiev alexei.lavrentev@ens-lyon.fr</xd:author>
36
		<xd:copyright>2015, CNRS / ICAR (Équipe CACTUS)</xd:copyright>
37
	</xd:doc>
38

    
39
	<!--<xsl:strip-space elements="*"/> -->
40

    
41
	<xsl:param name="baseMsSiglum">
42
		A
43
	</xsl:param>
44

    
45
	<xsl:variable name="baseMsPattern">
46
		<xsl:value-of
47
			select="concat('^#?',$baseMsSiglum,'| #?',$baseMsSiglum)" />
48
	</xsl:variable>
49

    
50
	<xsl:template match="*|comment()">
51
		<!-- Copy the current node -->
52
		<xsl:copy>
53
			<!-- Including any attributes it has and any child nodes -->
54
			<xsl:apply-templates select="@*|node()" />
55
		</xsl:copy>
56
	</xsl:template>
57

    
58
	<xsl:template match="processing-instruction()" />
59

    
60
	<!-- On supprime les attributs par défaut de la DTD TEI -->
61

    
62
	<xsl:template match="@*">
63
		<xsl:choose>
64
			<xsl:when
65
				test="matches(name(.),'^(part|instant|anchored|full)$')" />
66
			<xsl:otherwise>
67
				<xsl:copy />
68
			</xsl:otherwise>
69
		</xsl:choose>
70
	</xsl:template>
71

    
72
	<xsl:template match="@facs">
73
		<xsl:attribute name="facs">
74
   <xsl:choose>
75
     <xsl:when test="matches(.,'^http:')">
76
       <xsl:value-of
77
			select="substring-after(.,'nomFichier=')" />    
78
     </xsl:when>
79
     <xsl:otherwise>
80
       <xsl:value-of select="." />
81
     </xsl:otherwise>
82
   </xsl:choose>
83
   </xsl:attribute>
84
	</xsl:template>
85

    
86
	<xsl:template match="tei:teiHeader">
87
		<xsl:copy>
88
			<xsl:apply-templates select="@*" />
89
			<xsl:apply-templates />
90
		</xsl:copy>
91
	</xsl:template>
92

    
93

    
94
	<xsl:template match="tei:revisionDesc">
95
		<xsl:copy>
96
			<xsl:apply-templates select="@*" />
97
			<change xmlns="http://www.tei-c.org/ns/1.0" when="2007-01-01"
98
				who="#DS">Publication du document original</change>
99
			<!-- information récupérée à partir de /TEI/text[1]/front[1]/titlePage[1]/docDate[1] -->
100
			<change xmlns="http://www.tei-c.org/ns/1.0"
101
				when="{format-date(current-date(),'[Y]-[M01]-[D01]')}" who="#auto">Conversion
102
				automatique au format XML-TEI-Oriflamms</change>
103
			<xsl:apply-templates />
104
		</xsl:copy>
105
	</xsl:template>
106

    
107
	<xsl:template match="tei:encodingDesc">
108
		<xsl:copy>
109
			<xsl:apply-templates select="@*" />
110
			<xsl:apply-templates />
111
			<xsl:if test="not(//tei:prefixDef[@ident='ori'])">
112
				<listPrefixDef xmlns="http://www.tei-c.org/ns/1.0">
113
					<prefixDef xmlns="http://www.tei-c.org/ns/1.0"
114
						ident="ori" matchPattern="([a-z]+)"
115
						replacementPattern="oriflamms-annotation-scheme.xml#$1">
116
						<p>
117
							In the context of this project, private URIs with the prefix
118
							"ori" point to
119
							<gi>interp</gi>
120
							elements in the project's
121
							oriflamms-annotation-scheme.xml file.
122
						</p>
123
					</prefixDef>
124
				</listPrefixDef>
125
			</xsl:if>
126
		</xsl:copy>
127
	</xsl:template>
128

    
129
	<!-- On restructure le document pour avoir un TEI par charte -->
130

    
131
	<!-- TEI devient teiCorpus -->
132

    
133
	<xsl:template match="tei:TEI">
134
		<xsl:element name="teiCorpus"
135
			xmlns="http://www.tei-c.org/ns/1.0">
136
			<xsl:apply-templates select="@*" />
137
			<xsl:apply-templates />
138
		</xsl:element>
139
	</xsl:template>
140

    
141
	<!-- on supprime l'élément text de niveau 1 et travaille directement sur 
142
		le niveau 2 (l'élément group intermédiaire disparait) -->
143

    
144
	<xsl:template match="tei:TEI/tei:text">
145
		<xsl:apply-templates select="descendant::tei:text" />
146
	</xsl:template>
147

    
148
	<xsl:template match="tei:text//tei:text">
149

    
150
		<TEI xmlns="http://www.tei-c.org/ns/1.0">
151
			<teiHeader xmlns="http://www.tei-c.org/ns/1.0">
152
				<fileDesc xmlns="http://www.tei-c.org/ns/1.0">
153
					<titleStmt xmlns="http://www.tei-c.org/ns/1.0">
154
						<title xmlns="http://www.tei-c.org/ns/1.0">
155
							<xsl:text>Acte original </xsl:text>
156
							<xsl:value-of
157
								select="substring-after(preceding-sibling::comment()[contains(.,'acte original')][1],'acte original ')" />
158
						</title>
159
						<author xmlns="http://www.tei-c.org/ns/1.0">
160
							<xsl:value-of select="descendant::tei:docAuthor" />
161
						</author>
162
					</titleStmt>
163
					<publicationStmt
164
						xmlns="http://www.tei-c.org/ns/1.0">
165
						<p xmlns="http://www.tei-c.org/ns/1.0">See the header of the teiCorpus</p>
166
					</publicationStmt>
167
					<!-- les éléments listWit et listBibl sont placés dans sourceDesc -->
168
					<sourceDesc xmlns="http://www.tei-c.org/ns/1.0">
169
						<xsl:copy-of select="descendant::tei:listWit" />
170
						<xsl:copy-of select="descendant::tei:listBibl[1]"></xsl:copy-of>
171
					</sourceDesc>
172
				</fileDesc>
173
				<profileDesc xmlns="http://www.tei-c.org/ns/1.0">
174
					<!-- docDate devient profileDesc/creation/date[@type='documentCreation'] -->
175
					<creation xmlns="http://www.tei-c.org/ns/1.0">
176
						<xsl:apply-templates
177
							select="descendant::tei:docDate" />
178
					</creation>
179
					<!-- argument devient profileDesc/abstract -->
180
					<xsl:apply-templates
181
						select="descendant::tei:argument" />
182
				</profileDesc>
183
			</teiHeader>
184
			<text xmlns="http://www.tei-c.org/ns/1.0">
185
				<xsl:apply-templates />
186
			</text>
187
		</TEI>
188
	</xsl:template>
189

    
190
	<!-- on supprime listWit du corps du texte (cf. l'entête) -->
191
	<xsl:template match="tei:listWit" />
192

    
193
	<!-- on supprime les entêtes et pied de pages (non alignables) -->
194

    
195
	<xsl:template match="tei:fw">
196
		<xsl:comment>
197
			fw :
198
			<xsl:copy-of select="." />
199
		</xsl:comment>
200
	</xsl:template>
201

    
202
	<!-- on ajoute un attribut pour faciliter l'identification des segments 
203
		à ne pas aligner -->
204

    
205
	<xsl:template
206
		match="tei:choice/tei:expan|tei:choice/tei:corr|tei:supplied|tei:note">
207
		<xsl:copy>
208
			<xsl:apply-templates select="@*" />
209
			<xsl:attribute name="ana">ori:align-no</xsl:attribute>
210
			<xsl:apply-templates />
211
		</xsl:copy>
212
	</xsl:template>
213

    
214

    
215
	<xsl:template
216
		match="text()[following-sibling::*[1][self::tei:milestone or self::tei:pb or self::tei:cb or self::tei:lb] and following-sibling::tei:lb[1][@break='no']]">
217
		<xsl:choose>
218
			<!-- patch d'espace blanc devant les sauts de ligne à l'intérieur de mots -->
219
			<xsl:when test="matches(.,'\s+$')">
220
				<xsl:value-of select="replace(.,'\s+$','')" />
221
			</xsl:when>
222
			<xsl:otherwise>
223
				<xsl:copy />
224
			</xsl:otherwise>
225
		</xsl:choose>
226
	</xsl:template>
227

    
228
</xsl:stylesheet>