Laboratoire ICAR » Plateforme TXM

set installdir=%~dp0

set ARGS=%*

set DEBUG=0

set VERSION=0.8.0

set USERHOME=%USERPROFILE%\

IF NOT EXIST ROAMINGINSTALL GOTO ROAMINGINSTALLDONE

echo "The 'roaming' install option is set."

set USERHOME=%HOMEDRIVE%%HOMEPATH%\

echo "USERHOME set to %USERHOME%"

:ROAMINGINSTALLDONE

IF NOT EXIST ASKUSERDIRECTORY GOTO ASKUSERDIRECTORYDONE

echo "The 'ask user directory' install option is set."

for /f "tokens=*" %%a in ('jre\bin\java -jar StartDialog.jar') do set USERHOME=%%a\

echo "USERHOME set to %USERHOME%"

:ASKUSERDIRECTORYDONE

IF EXIST "%USERHOME%" GOTO USERHOMEOK

echo "%USERHOME% does not exist. Aborting"

msg * "TXM could not start using the USERHOME='%USERHOME%' directory."

GOTO:EOF

:USERHOMEOK

set TXMHOME=%USERHOME%TXM-%VERSION%\

set DOTTXM=%TXMHOME%.txm\

mkdir "%TXMHOME%"

mkdir "%DOTTXM%"

echo "TXM: getting install date from %installdir%STAMP and %DOTTXM%STAMP files"

Fc "%installdir%STAMP" "%DOTTXM%STAMP"

IF errorlevel 1 (goto :install) else (goto :run)

:install

echo "New TXM install: it's the first launch after the installation."

del "%temp%\org.txm.rcpapplication.prefs"

copy "%DOTTXM%configuration\.settings\org.txm.rcpapplication.prefs" "%temp%\org.txm.rcpapplication.prefs"

copy "%DOTTXM%.metadata\.plugins\org.eclipse.core.runtime\.settings\org.txm.rcpapplication.prefs" "%temp%\org.txm.rcpapplication.prefs"

copy "%DOTTXM%data\.metadata\.plugins\org.eclipse.core.runtime\.settings\org.txm.rcpapplication.prefs" "%temp%\org.txm.rcpapplication.prefs"

rmdir /s /q "%DOTTXM%"

IF errorlevel 1 (echo "TXM: failed to delete the %DOTTXM% directory.")

mkdir "%DOTTXM%"

IF errorlevel 1 (echo "TXM: failed to create %DOTTXM% directory.")

copy "%installdir%TXM.ini" "%DOTTXM%TXM.ini"

IF errorlevel 1 (echo "TXM: failed to copy %DOTTXM%TXM.ini file")

copy "%temp%\org.txm.rcpapplication.prefs" "%DOTTXM%org.txm.rcpapplication.prefs"

mkdir "%DOTTXM%user"

IF errorlevel 1 (echo "TXM: failed to create %DOTTXM%user directory.")

mkdir "%DOTTXM%data"

IF errorlevel 1 (echo "TXM: failed to create %DOTTXM%data directory.")

rmdir /s /q "%TXMHOME%corpora\.metadata"

IF errorlevel 1 (echo "TXM: failed to delete the %TXMHOME%corpora\.metadata directory.")

copy "%installdir%STAMP" "%DOTTXM%STAMP"

IF errorlevel 1 (echo "TXM: failed to copy %DOTTXM%STAMP file")

:run

set _JAVA_OPTIONS=-Duser.home="%USERHOME%"

echo running "%installdir%TXM.exe" -run --launcher.ini "%DOTTXM%TXM.ini" %ARGS% -data "%DOTTXM%data" -user "%DOTTXM%user" -install "%installdir%"

REM "%installdir%TXM.exe" -run --launcher.ini "%DOTTXM%TXM.ini" %ARGS% -data "%DOTTXM%corpora" -user "%DOTTXM%user" -install "%installdir%"

"%installdir%TXM.exe" -run --launcher.ini "%DOTTXM%TXM.ini" %ARGS% -data "%TXMHOME%corpora" -user "%DOTTXM%user" -install "%installdir%\"