root / src / blas / dsymm.f @ 4
Historique | Voir | Annoter | Télécharger (9,37 ko)
| 1 | 1 | equemene | SUBROUTINE DSYMM(SIDE,UPLO,M,N,ALPHA,A,LDA,B,LDB,BETA,C,LDC) |
|---|---|---|---|
| 2 | 1 | equemene | * .. Scalar Arguments .. |
| 3 | 1 | equemene | DOUBLE PRECISION ALPHA,BETA |
| 4 | 1 | equemene | INTEGER LDA,LDB,LDC,M,N |
| 5 | 1 | equemene | CHARACTER SIDE,UPLO |
| 6 | 1 | equemene | * .. |
| 7 | 1 | equemene | * .. Array Arguments .. |
| 8 | 1 | equemene | DOUBLE PRECISION A(LDA,*),B(LDB,*),C(LDC,*) |
| 9 | 1 | equemene | * .. |
| 10 | 1 | equemene | * |
| 11 | 1 | equemene | * Purpose |
| 12 | 1 | equemene | * ======= |
| 13 | 1 | equemene | * |
| 14 | 1 | equemene | * DSYMM performs one of the matrix-matrix operations |
| 15 | 1 | equemene | * |
| 16 | 1 | equemene | * C := alpha*A*B + beta*C, |
| 17 | 1 | equemene | * |
| 18 | 1 | equemene | * or |
| 19 | 1 | equemene | * |
| 20 | 1 | equemene | * C := alpha*B*A + beta*C, |
| 21 | 1 | equemene | * |
| 22 | 1 | equemene | * where alpha and beta are scalars, A is a symmetric matrix and B and |
| 23 | 1 | equemene | * C are m by n matrices. |
| 24 | 1 | equemene | * |
| 25 | 1 | equemene | * Arguments |
| 26 | 1 | equemene | * ========== |
| 27 | 1 | equemene | * |
| 28 | 1 | equemene | * SIDE - CHARACTER*1. |
| 29 | 1 | equemene | * On entry, SIDE specifies whether the symmetric matrix A |
| 30 | 1 | equemene | * appears on the left or right in the operation as follows: |
| 31 | 1 | equemene | * |
| 32 | 1 | equemene | * SIDE = 'L' or 'l' C := alpha*A*B + beta*C, |
| 33 | 1 | equemene | * |
| 34 | 1 | equemene | * SIDE = 'R' or 'r' C := alpha*B*A + beta*C, |
| 35 | 1 | equemene | * |
| 36 | 1 | equemene | * Unchanged on exit. |
| 37 | 1 | equemene | * |
| 38 | 1 | equemene | * UPLO - CHARACTER*1. |
| 39 | 1 | equemene | * On entry, UPLO specifies whether the upper or lower |
| 40 | 1 | equemene | * triangular part of the symmetric matrix A is to be |
| 41 | 1 | equemene | * referenced as follows: |
| 42 | 1 | equemene | * |
| 43 | 1 | equemene | * UPLO = 'U' or 'u' Only the upper triangular part of the |
| 44 | 1 | equemene | * symmetric matrix is to be referenced. |
| 45 | 1 | equemene | * |
| 46 | 1 | equemene | * UPLO = 'L' or 'l' Only the lower triangular part of the |
| 47 | 1 | equemene | * symmetric matrix is to be referenced. |
| 48 | 1 | equemene | * |
| 49 | 1 | equemene | * Unchanged on exit. |
| 50 | 1 | equemene | * |
| 51 | 1 | equemene | * M - INTEGER. |
| 52 | 1 | equemene | * On entry, M specifies the number of rows of the matrix C. |
| 53 | 1 | equemene | * M must be at least zero. |
| 54 | 1 | equemene | * Unchanged on exit. |
| 55 | 1 | equemene | * |
| 56 | 1 | equemene | * N - INTEGER. |
| 57 | 1 | equemene | * On entry, N specifies the number of columns of the matrix C. |
| 58 | 1 | equemene | * N must be at least zero. |
| 59 | 1 | equemene | * Unchanged on exit. |
| 60 | 1 | equemene | * |
| 61 | 1 | equemene | * ALPHA - DOUBLE PRECISION. |
| 62 | 1 | equemene | * On entry, ALPHA specifies the scalar alpha. |
| 63 | 1 | equemene | * Unchanged on exit. |
| 64 | 1 | equemene | * |
| 65 | 1 | equemene | * A - DOUBLE PRECISION array of DIMENSION ( LDA, ka ), where ka is |
| 66 | 1 | equemene | * m when SIDE = 'L' or 'l' and is n otherwise. |
| 67 | 1 | equemene | * Before entry with SIDE = 'L' or 'l', the m by m part of |
| 68 | 1 | equemene | * the array A must contain the symmetric matrix, such that |
| 69 | 1 | equemene | * when UPLO = 'U' or 'u', the leading m by m upper triangular |
| 70 | 1 | equemene | * part of the array A must contain the upper triangular part |
| 71 | 1 | equemene | * of the symmetric matrix and the strictly lower triangular |
| 72 | 1 | equemene | * part of A is not referenced, and when UPLO = 'L' or 'l', |
| 73 | 1 | equemene | * the leading m by m lower triangular part of the array A |
| 74 | 1 | equemene | * must contain the lower triangular part of the symmetric |
| 75 | 1 | equemene | * matrix and the strictly upper triangular part of A is not |
| 76 | 1 | equemene | * referenced. |
| 77 | 1 | equemene | * Before entry with SIDE = 'R' or 'r', the n by n part of |
| 78 | 1 | equemene | * the array A must contain the symmetric matrix, such that |
| 79 | 1 | equemene | * when UPLO = 'U' or 'u', the leading n by n upper triangular |
| 80 | 1 | equemene | * part of the array A must contain the upper triangular part |
| 81 | 1 | equemene | * of the symmetric matrix and the strictly lower triangular |
| 82 | 1 | equemene | * part of A is not referenced, and when UPLO = 'L' or 'l', |
| 83 | 1 | equemene | * the leading n by n lower triangular part of the array A |
| 84 | 1 | equemene | * must contain the lower triangular part of the symmetric |
| 85 | 1 | equemene | * matrix and the strictly upper triangular part of A is not |
| 86 | 1 | equemene | * referenced. |
| 87 | 1 | equemene | * Unchanged on exit. |
| 88 | 1 | equemene | * |
| 89 | 1 | equemene | * LDA - INTEGER. |
| 90 | 1 | equemene | * On entry, LDA specifies the first dimension of A as declared |
| 91 | 1 | equemene | * in the calling (sub) program. When SIDE = 'L' or 'l' then |
| 92 | 1 | equemene | * LDA must be at least max( 1, m ), otherwise LDA must be at |
| 93 | 1 | equemene | * least max( 1, n ). |
| 94 | 1 | equemene | * Unchanged on exit. |
| 95 | 1 | equemene | * |
| 96 | 1 | equemene | * B - DOUBLE PRECISION array of DIMENSION ( LDB, n ). |
| 97 | 1 | equemene | * Before entry, the leading m by n part of the array B must |
| 98 | 1 | equemene | * contain the matrix B. |
| 99 | 1 | equemene | * Unchanged on exit. |
| 100 | 1 | equemene | * |
| 101 | 1 | equemene | * LDB - INTEGER. |
| 102 | 1 | equemene | * On entry, LDB specifies the first dimension of B as declared |
| 103 | 1 | equemene | * in the calling (sub) program. LDB must be at least |
| 104 | 1 | equemene | * max( 1, m ). |
| 105 | 1 | equemene | * Unchanged on exit. |
| 106 | 1 | equemene | * |
| 107 | 1 | equemene | * BETA - DOUBLE PRECISION. |
| 108 | 1 | equemene | * On entry, BETA specifies the scalar beta. When BETA is |
| 109 | 1 | equemene | * supplied as zero then C need not be set on input. |
| 110 | 1 | equemene | * Unchanged on exit. |
| 111 | 1 | equemene | * |
| 112 | 1 | equemene | * C - DOUBLE PRECISION array of DIMENSION ( LDC, n ). |
| 113 | 1 | equemene | * Before entry, the leading m by n part of the array C must |
| 114 | 1 | equemene | * contain the matrix C, except when beta is zero, in which |
| 115 | 1 | equemene | * case C need not be set on entry. |
| 116 | 1 | equemene | * On exit, the array C is overwritten by the m by n updated |
| 117 | 1 | equemene | * matrix. |
| 118 | 1 | equemene | * |
| 119 | 1 | equemene | * LDC - INTEGER. |
| 120 | 1 | equemene | * On entry, LDC specifies the first dimension of C as declared |
| 121 | 1 | equemene | * in the calling (sub) program. LDC must be at least |
| 122 | 1 | equemene | * max( 1, m ). |
| 123 | 1 | equemene | * Unchanged on exit. |
| 124 | 1 | equemene | * |
| 125 | 1 | equemene | * |
| 126 | 1 | equemene | * Level 3 Blas routine. |
| 127 | 1 | equemene | * |
| 128 | 1 | equemene | * -- Written on 8-February-1989. |
| 129 | 1 | equemene | * Jack Dongarra, Argonne National Laboratory. |
| 130 | 1 | equemene | * Iain Duff, AERE Harwell. |
| 131 | 1 | equemene | * Jeremy Du Croz, Numerical Algorithms Group Ltd. |
| 132 | 1 | equemene | * Sven Hammarling, Numerical Algorithms Group Ltd. |
| 133 | 1 | equemene | * |
| 134 | 1 | equemene | * |
| 135 | 1 | equemene | * .. External Functions .. |
| 136 | 1 | equemene | LOGICAL LSAME |
| 137 | 1 | equemene | EXTERNAL LSAME |
| 138 | 1 | equemene | * .. |
| 139 | 1 | equemene | * .. External Subroutines .. |
| 140 | 1 | equemene | EXTERNAL XERBLA |
| 141 | 1 | equemene | * .. |
| 142 | 1 | equemene | * .. Intrinsic Functions .. |
| 143 | 1 | equemene | INTRINSIC MAX |
| 144 | 1 | equemene | * .. |
| 145 | 1 | equemene | * .. Local Scalars .. |
| 146 | 1 | equemene | DOUBLE PRECISION TEMP1,TEMP2 |
| 147 | 1 | equemene | INTEGER I,INFO,J,K,NROWA |
| 148 | 1 | equemene | LOGICAL UPPER |
| 149 | 1 | equemene | * .. |
| 150 | 1 | equemene | * .. Parameters .. |
| 151 | 1 | equemene | DOUBLE PRECISION ONE,ZERO |
| 152 | 1 | equemene | PARAMETER (ONE=1.0D+0,ZERO=0.0D+0) |
| 153 | 1 | equemene | * .. |
| 154 | 1 | equemene | * |
| 155 | 1 | equemene | * Set NROWA as the number of rows of A. |
| 156 | 1 | equemene | * |
| 157 | 1 | equemene | IF (LSAME(SIDE,'L')) THEN |
| 158 | 1 | equemene | NROWA = M |
| 159 | 1 | equemene | ELSE |
| 160 | 1 | equemene | NROWA = N |
| 161 | 1 | equemene | END IF |
| 162 | 1 | equemene | UPPER = LSAME(UPLO,'U') |
| 163 | 1 | equemene | * |
| 164 | 1 | equemene | * Test the input parameters. |
| 165 | 1 | equemene | * |
| 166 | 1 | equemene | INFO = 0 |
| 167 | 1 | equemene | IF ((.NOT.LSAME(SIDE,'L')) .AND. (.NOT.LSAME(SIDE,'R'))) THEN |
| 168 | 1 | equemene | INFO = 1 |
| 169 | 1 | equemene | ELSE IF ((.NOT.UPPER) .AND. (.NOT.LSAME(UPLO,'L'))) THEN |
| 170 | 1 | equemene | INFO = 2 |
| 171 | 1 | equemene | ELSE IF (M.LT.0) THEN |
| 172 | 1 | equemene | INFO = 3 |
| 173 | 1 | equemene | ELSE IF (N.LT.0) THEN |
| 174 | 1 | equemene | INFO = 4 |
| 175 | 1 | equemene | ELSE IF (LDA.LT.MAX(1,NROWA)) THEN |
| 176 | 1 | equemene | INFO = 7 |
| 177 | 1 | equemene | ELSE IF (LDB.LT.MAX(1,M)) THEN |
| 178 | 1 | equemene | INFO = 9 |
| 179 | 1 | equemene | ELSE IF (LDC.LT.MAX(1,M)) THEN |
| 180 | 1 | equemene | INFO = 12 |
| 181 | 1 | equemene | END IF |
| 182 | 1 | equemene | IF (INFO.NE.0) THEN |
| 183 | 1 | equemene | CALL XERBLA('DSYMM ',INFO)
|
| 184 | 1 | equemene | RETURN |
| 185 | 1 | equemene | END IF |
| 186 | 1 | equemene | * |
| 187 | 1 | equemene | * Quick return if possible. |
| 188 | 1 | equemene | * |
| 189 | 1 | equemene | IF ((M.EQ.0) .OR. (N.EQ.0) .OR. |
| 190 | 1 | equemene | + ((ALPHA.EQ.ZERO).AND. (BETA.EQ.ONE))) RETURN |
| 191 | 1 | equemene | * |
| 192 | 1 | equemene | * And when alpha.eq.zero. |
| 193 | 1 | equemene | * |
| 194 | 1 | equemene | IF (ALPHA.EQ.ZERO) THEN |
| 195 | 1 | equemene | IF (BETA.EQ.ZERO) THEN |
| 196 | 1 | equemene | DO 20 J = 1,N |
| 197 | 1 | equemene | DO 10 I = 1,M |
| 198 | 1 | equemene | C(I,J) = ZERO |
| 199 | 1 | equemene | 10 CONTINUE |
| 200 | 1 | equemene | 20 CONTINUE |
| 201 | 1 | equemene | ELSE |
| 202 | 1 | equemene | DO 40 J = 1,N |
| 203 | 1 | equemene | DO 30 I = 1,M |
| 204 | 1 | equemene | C(I,J) = BETA*C(I,J) |
| 205 | 1 | equemene | 30 CONTINUE |
| 206 | 1 | equemene | 40 CONTINUE |
| 207 | 1 | equemene | END IF |
| 208 | 1 | equemene | RETURN |
| 209 | 1 | equemene | END IF |
| 210 | 1 | equemene | * |
| 211 | 1 | equemene | * Start the operations. |
| 212 | 1 | equemene | * |
| 213 | 1 | equemene | IF (LSAME(SIDE,'L')) THEN |
| 214 | 1 | equemene | * |
| 215 | 1 | equemene | * Form C := alpha*A*B + beta*C. |
| 216 | 1 | equemene | * |
| 217 | 1 | equemene | IF (UPPER) THEN |
| 218 | 1 | equemene | DO 70 J = 1,N |
| 219 | 1 | equemene | DO 60 I = 1,M |
| 220 | 1 | equemene | TEMP1 = ALPHA*B(I,J) |
| 221 | 1 | equemene | TEMP2 = ZERO |
| 222 | 1 | equemene | DO 50 K = 1,I - 1 |
| 223 | 1 | equemene | C(K,J) = C(K,J) + TEMP1*A(K,I) |
| 224 | 1 | equemene | TEMP2 = TEMP2 + B(K,J)*A(K,I) |
| 225 | 1 | equemene | 50 CONTINUE |
| 226 | 1 | equemene | IF (BETA.EQ.ZERO) THEN |
| 227 | 1 | equemene | C(I,J) = TEMP1*A(I,I) + ALPHA*TEMP2 |
| 228 | 1 | equemene | ELSE |
| 229 | 1 | equemene | C(I,J) = BETA*C(I,J) + TEMP1*A(I,I) + |
| 230 | 1 | equemene | + ALPHA*TEMP2 |
| 231 | 1 | equemene | END IF |
| 232 | 1 | equemene | 60 CONTINUE |
| 233 | 1 | equemene | 70 CONTINUE |
| 234 | 1 | equemene | ELSE |
| 235 | 1 | equemene | DO 100 J = 1,N |
| 236 | 1 | equemene | DO 90 I = M,1,-1 |
| 237 | 1 | equemene | TEMP1 = ALPHA*B(I,J) |
| 238 | 1 | equemene | TEMP2 = ZERO |
| 239 | 1 | equemene | DO 80 K = I + 1,M |
| 240 | 1 | equemene | C(K,J) = C(K,J) + TEMP1*A(K,I) |
| 241 | 1 | equemene | TEMP2 = TEMP2 + B(K,J)*A(K,I) |
| 242 | 1 | equemene | 80 CONTINUE |
| 243 | 1 | equemene | IF (BETA.EQ.ZERO) THEN |
| 244 | 1 | equemene | C(I,J) = TEMP1*A(I,I) + ALPHA*TEMP2 |
| 245 | 1 | equemene | ELSE |
| 246 | 1 | equemene | C(I,J) = BETA*C(I,J) + TEMP1*A(I,I) + |
| 247 | 1 | equemene | + ALPHA*TEMP2 |
| 248 | 1 | equemene | END IF |
| 249 | 1 | equemene | 90 CONTINUE |
| 250 | 1 | equemene | 100 CONTINUE |
| 251 | 1 | equemene | END IF |
| 252 | 1 | equemene | ELSE |
| 253 | 1 | equemene | * |
| 254 | 1 | equemene | * Form C := alpha*B*A + beta*C. |
| 255 | 1 | equemene | * |
| 256 | 1 | equemene | DO 170 J = 1,N |
| 257 | 1 | equemene | TEMP1 = ALPHA*A(J,J) |
| 258 | 1 | equemene | IF (BETA.EQ.ZERO) THEN |
| 259 | 1 | equemene | DO 110 I = 1,M |
| 260 | 1 | equemene | C(I,J) = TEMP1*B(I,J) |
| 261 | 1 | equemene | 110 CONTINUE |
| 262 | 1 | equemene | ELSE |
| 263 | 1 | equemene | DO 120 I = 1,M |
| 264 | 1 | equemene | C(I,J) = BETA*C(I,J) + TEMP1*B(I,J) |
| 265 | 1 | equemene | 120 CONTINUE |
| 266 | 1 | equemene | END IF |
| 267 | 1 | equemene | DO 140 K = 1,J - 1 |
| 268 | 1 | equemene | IF (UPPER) THEN |
| 269 | 1 | equemene | TEMP1 = ALPHA*A(K,J) |
| 270 | 1 | equemene | ELSE |
| 271 | 1 | equemene | TEMP1 = ALPHA*A(J,K) |
| 272 | 1 | equemene | END IF |
| 273 | 1 | equemene | DO 130 I = 1,M |
| 274 | 1 | equemene | C(I,J) = C(I,J) + TEMP1*B(I,K) |
| 275 | 1 | equemene | 130 CONTINUE |
| 276 | 1 | equemene | 140 CONTINUE |
| 277 | 1 | equemene | DO 160 K = J + 1,N |
| 278 | 1 | equemene | IF (UPPER) THEN |
| 279 | 1 | equemene | TEMP1 = ALPHA*A(J,K) |
| 280 | 1 | equemene | ELSE |
| 281 | 1 | equemene | TEMP1 = ALPHA*A(K,J) |
| 282 | 1 | equemene | END IF |
| 283 | 1 | equemene | DO 150 I = 1,M |
| 284 | 1 | equemene | C(I,J) = C(I,J) + TEMP1*B(I,K) |
| 285 | 1 | equemene | 150 CONTINUE |
| 286 | 1 | equemene | 160 CONTINUE |
| 287 | 1 | equemene | 170 CONTINUE |
| 288 | 1 | equemene | END IF |
| 289 | 1 | equemene | * |
| 290 | 1 | equemene | RETURN |
| 291 | 1 | equemene | * |
| 292 | 1 | equemene | * End of DSYMM . |
| 293 | 1 | equemene | * |
| 294 | 1 | equemene | END |