root / src / lapack / double / dgeqrf.f @ 2
Historique | Voir | Annoter | Télécharger (5,74 ko)
| 1 | 1 | equemene | SUBROUTINE DGEQRF( M, N, A, LDA, TAU, WORK, LWORK, INFO ) |
|---|---|---|---|
| 2 | 1 | equemene | * |
| 3 | 1 | equemene | * -- LAPACK routine (version 3.2) -- |
| 4 | 1 | equemene | * -- LAPACK is a software package provided by Univ. of Tennessee, -- |
| 5 | 1 | equemene | * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..-- |
| 6 | 1 | equemene | * November 2006 |
| 7 | 1 | equemene | * |
| 8 | 1 | equemene | * .. Scalar Arguments .. |
| 9 | 1 | equemene | INTEGER INFO, LDA, LWORK, M, N |
| 10 | 1 | equemene | * .. |
| 11 | 1 | equemene | * .. Array Arguments .. |
| 12 | 1 | equemene | DOUBLE PRECISION A( LDA, * ), TAU( * ), WORK( * ) |
| 13 | 1 | equemene | * .. |
| 14 | 1 | equemene | * |
| 15 | 1 | equemene | * Purpose |
| 16 | 1 | equemene | * ======= |
| 17 | 1 | equemene | * |
| 18 | 1 | equemene | * DGEQRF computes a QR factorization of a real M-by-N matrix A: |
| 19 | 1 | equemene | * A = Q * R. |
| 20 | 1 | equemene | * |
| 21 | 1 | equemene | * Arguments |
| 22 | 1 | equemene | * ========= |
| 23 | 1 | equemene | * |
| 24 | 1 | equemene | * M (input) INTEGER |
| 25 | 1 | equemene | * The number of rows of the matrix A. M >= 0. |
| 26 | 1 | equemene | * |
| 27 | 1 | equemene | * N (input) INTEGER |
| 28 | 1 | equemene | * The number of columns of the matrix A. N >= 0. |
| 29 | 1 | equemene | * |
| 30 | 1 | equemene | * A (input/output) DOUBLE PRECISION array, dimension (LDA,N) |
| 31 | 1 | equemene | * On entry, the M-by-N matrix A. |
| 32 | 1 | equemene | * On exit, the elements on and above the diagonal of the array |
| 33 | 1 | equemene | * contain the min(M,N)-by-N upper trapezoidal matrix R (R is |
| 34 | 1 | equemene | * upper triangular if m >= n); the elements below the diagonal, |
| 35 | 1 | equemene | * with the array TAU, represent the orthogonal matrix Q as a |
| 36 | 1 | equemene | * product of min(m,n) elementary reflectors (see Further |
| 37 | 1 | equemene | * Details). |
| 38 | 1 | equemene | * |
| 39 | 1 | equemene | * LDA (input) INTEGER |
| 40 | 1 | equemene | * The leading dimension of the array A. LDA >= max(1,M). |
| 41 | 1 | equemene | * |
| 42 | 1 | equemene | * TAU (output) DOUBLE PRECISION array, dimension (min(M,N)) |
| 43 | 1 | equemene | * The scalar factors of the elementary reflectors (see Further |
| 44 | 1 | equemene | * Details). |
| 45 | 1 | equemene | * |
| 46 | 1 | equemene | * WORK (workspace/output) DOUBLE PRECISION array, dimension (MAX(1,LWORK)) |
| 47 | 1 | equemene | * On exit, if INFO = 0, WORK(1) returns the optimal LWORK. |
| 48 | 1 | equemene | * |
| 49 | 1 | equemene | * LWORK (input) INTEGER |
| 50 | 1 | equemene | * The dimension of the array WORK. LWORK >= max(1,N). |
| 51 | 1 | equemene | * For optimum performance LWORK >= N*NB, where NB is |
| 52 | 1 | equemene | * the optimal blocksize. |
| 53 | 1 | equemene | * |
| 54 | 1 | equemene | * If LWORK = -1, then a workspace query is assumed; the routine |
| 55 | 1 | equemene | * only calculates the optimal size of the WORK array, returns |
| 56 | 1 | equemene | * this value as the first entry of the WORK array, and no error |
| 57 | 1 | equemene | * message related to LWORK is issued by XERBLA. |
| 58 | 1 | equemene | * |
| 59 | 1 | equemene | * INFO (output) INTEGER |
| 60 | 1 | equemene | * = 0: successful exit |
| 61 | 1 | equemene | * < 0: if INFO = -i, the i-th argument had an illegal value |
| 62 | 1 | equemene | * |
| 63 | 1 | equemene | * Further Details |
| 64 | 1 | equemene | * =============== |
| 65 | 1 | equemene | * |
| 66 | 1 | equemene | * The matrix Q is represented as a product of elementary reflectors |
| 67 | 1 | equemene | * |
| 68 | 1 | equemene | * Q = H(1) H(2) . . . H(k), where k = min(m,n). |
| 69 | 1 | equemene | * |
| 70 | 1 | equemene | * Each H(i) has the form |
| 71 | 1 | equemene | * |
| 72 | 1 | equemene | * H(i) = I - tau * v * v' |
| 73 | 1 | equemene | * |
| 74 | 1 | equemene | * where tau is a real scalar, and v is a real vector with |
| 75 | 1 | equemene | * v(1:i-1) = 0 and v(i) = 1; v(i+1:m) is stored on exit in A(i+1:m,i), |
| 76 | 1 | equemene | * and tau in TAU(i). |
| 77 | 1 | equemene | * |
| 78 | 1 | equemene | * ===================================================================== |
| 79 | 1 | equemene | * |
| 80 | 1 | equemene | * .. Local Scalars .. |
| 81 | 1 | equemene | LOGICAL LQUERY |
| 82 | 1 | equemene | INTEGER I, IB, IINFO, IWS, K, LDWORK, LWKOPT, NB, |
| 83 | 1 | equemene | $ NBMIN, NX |
| 84 | 1 | equemene | * .. |
| 85 | 1 | equemene | * .. External Subroutines .. |
| 86 | 1 | equemene | EXTERNAL DGEQR2, DLARFB, DLARFT, XERBLA |
| 87 | 1 | equemene | * .. |
| 88 | 1 | equemene | * .. Intrinsic Functions .. |
| 89 | 1 | equemene | INTRINSIC MAX, MIN |
| 90 | 1 | equemene | * .. |
| 91 | 1 | equemene | * .. External Functions .. |
| 92 | 1 | equemene | INTEGER ILAENV |
| 93 | 1 | equemene | EXTERNAL ILAENV |
| 94 | 1 | equemene | * .. |
| 95 | 1 | equemene | * .. Executable Statements .. |
| 96 | 1 | equemene | * |
| 97 | 1 | equemene | * Test the input arguments |
| 98 | 1 | equemene | * |
| 99 | 1 | equemene | INFO = 0 |
| 100 | 1 | equemene | NB = ILAENV( 1, 'DGEQRF', ' ', M, N, -1, -1 ) |
| 101 | 1 | equemene | LWKOPT = N*NB |
| 102 | 1 | equemene | WORK( 1 ) = LWKOPT |
| 103 | 1 | equemene | LQUERY = ( LWORK.EQ.-1 ) |
| 104 | 1 | equemene | IF( M.LT.0 ) THEN |
| 105 | 1 | equemene | INFO = -1 |
| 106 | 1 | equemene | ELSE IF( N.LT.0 ) THEN |
| 107 | 1 | equemene | INFO = -2 |
| 108 | 1 | equemene | ELSE IF( LDA.LT.MAX( 1, M ) ) THEN |
| 109 | 1 | equemene | INFO = -4 |
| 110 | 1 | equemene | ELSE IF( LWORK.LT.MAX( 1, N ) .AND. .NOT.LQUERY ) THEN |
| 111 | 1 | equemene | INFO = -7 |
| 112 | 1 | equemene | END IF |
| 113 | 1 | equemene | IF( INFO.NE.0 ) THEN |
| 114 | 1 | equemene | CALL XERBLA( 'DGEQRF', -INFO ) |
| 115 | 1 | equemene | RETURN |
| 116 | 1 | equemene | ELSE IF( LQUERY ) THEN |
| 117 | 1 | equemene | RETURN |
| 118 | 1 | equemene | END IF |
| 119 | 1 | equemene | * |
| 120 | 1 | equemene | * Quick return if possible |
| 121 | 1 | equemene | * |
| 122 | 1 | equemene | K = MIN( M, N ) |
| 123 | 1 | equemene | IF( K.EQ.0 ) THEN |
| 124 | 1 | equemene | WORK( 1 ) = 1 |
| 125 | 1 | equemene | RETURN |
| 126 | 1 | equemene | END IF |
| 127 | 1 | equemene | * |
| 128 | 1 | equemene | NBMIN = 2 |
| 129 | 1 | equemene | NX = 0 |
| 130 | 1 | equemene | IWS = N |
| 131 | 1 | equemene | IF( NB.GT.1 .AND. NB.LT.K ) THEN |
| 132 | 1 | equemene | * |
| 133 | 1 | equemene | * Determine when to cross over from blocked to unblocked code. |
| 134 | 1 | equemene | * |
| 135 | 1 | equemene | NX = MAX( 0, ILAENV( 3, 'DGEQRF', ' ', M, N, -1, -1 ) ) |
| 136 | 1 | equemene | IF( NX.LT.K ) THEN |
| 137 | 1 | equemene | * |
| 138 | 1 | equemene | * Determine if workspace is large enough for blocked code. |
| 139 | 1 | equemene | * |
| 140 | 1 | equemene | LDWORK = N |
| 141 | 1 | equemene | IWS = LDWORK*NB |
| 142 | 1 | equemene | IF( LWORK.LT.IWS ) THEN |
| 143 | 1 | equemene | * |
| 144 | 1 | equemene | * Not enough workspace to use optimal NB: reduce NB and |
| 145 | 1 | equemene | * determine the minimum value of NB. |
| 146 | 1 | equemene | * |
| 147 | 1 | equemene | NB = LWORK / LDWORK |
| 148 | 1 | equemene | NBMIN = MAX( 2, ILAENV( 2, 'DGEQRF', ' ', M, N, -1, |
| 149 | 1 | equemene | $ -1 ) ) |
| 150 | 1 | equemene | END IF |
| 151 | 1 | equemene | END IF |
| 152 | 1 | equemene | END IF |
| 153 | 1 | equemene | * |
| 154 | 1 | equemene | IF( NB.GE.NBMIN .AND. NB.LT.K .AND. NX.LT.K ) THEN |
| 155 | 1 | equemene | * |
| 156 | 1 | equemene | * Use blocked code initially |
| 157 | 1 | equemene | * |
| 158 | 1 | equemene | DO 10 I = 1, K - NX, NB |
| 159 | 1 | equemene | IB = MIN( K-I+1, NB ) |
| 160 | 1 | equemene | * |
| 161 | 1 | equemene | * Compute the QR factorization of the current block |
| 162 | 1 | equemene | * A(i:m,i:i+ib-1) |
| 163 | 1 | equemene | * |
| 164 | 1 | equemene | CALL DGEQR2( M-I+1, IB, A( I, I ), LDA, TAU( I ), WORK, |
| 165 | 1 | equemene | $ IINFO ) |
| 166 | 1 | equemene | IF( I+IB.LE.N ) THEN |
| 167 | 1 | equemene | * |
| 168 | 1 | equemene | * Form the triangular factor of the block reflector |
| 169 | 1 | equemene | * H = H(i) H(i+1) . . . H(i+ib-1) |
| 170 | 1 | equemene | * |
| 171 | 1 | equemene | CALL DLARFT( 'Forward', 'Columnwise', M-I+1, IB, |
| 172 | 1 | equemene | $ A( I, I ), LDA, TAU( I ), WORK, LDWORK ) |
| 173 | 1 | equemene | * |
| 174 | 1 | equemene | * Apply H' to A(i:m,i+ib:n) from the left |
| 175 | 1 | equemene | * |
| 176 | 1 | equemene | CALL DLARFB( 'Left', 'Transpose', 'Forward', |
| 177 | 1 | equemene | $ 'Columnwise', M-I+1, N-I-IB+1, IB, |
| 178 | 1 | equemene | $ A( I, I ), LDA, WORK, LDWORK, A( I, I+IB ), |
| 179 | 1 | equemene | $ LDA, WORK( IB+1 ), LDWORK ) |
| 180 | 1 | equemene | END IF |
| 181 | 1 | equemene | 10 CONTINUE |
| 182 | 1 | equemene | ELSE |
| 183 | 1 | equemene | I = 1 |
| 184 | 1 | equemene | END IF |
| 185 | 1 | equemene | * |
| 186 | 1 | equemene | * Use unblocked code to factor the last or only block. |
| 187 | 1 | equemene | * |
| 188 | 1 | equemene | IF( I.LE.K ) |
| 189 | 1 | equemene | $ CALL DGEQR2( M-I+1, N-I+1, A( I, I ), LDA, TAU( I ), WORK, |
| 190 | 1 | equemene | $ IINFO ) |
| 191 | 1 | equemene | * |
| 192 | 1 | equemene | WORK( 1 ) = IWS |
| 193 | 1 | equemene | RETURN |
| 194 | 1 | equemene | * |
| 195 | 1 | equemene | * End of DGEQRF |
| 196 | 1 | equemene | * |
| 197 | 1 | equemene | END |