Laboratoire RDP » Biophysics Team » FLORIVAR

//////////////////////////////////////////////////////////////////////////////////

//The script will process all your .lif files in the chosen folder.

//The stacks will be saved in subfolders named as the treated lif files.

print ("====================================");

print ("======== Macro lif2tif.ijm =========");

print ("====================================");

//Choose the directory containing your .lif file//

dir = getDirectory("Choose a directory")

setBatchMode(true);

list = getFileList(dir);

//Find .lif experiment//

for (FileInd=0; FileInd<list.length; FileInd++){

	FileName = list[FileInd];

	if(endsWith (FileName, "lif")){

		print ("### Processing ",FileName," ###");

		path = dir+FileName;

		ShortName=substring(FileName,0,indexOf(FileName,".lif"));

		print("Creating output directory ",ShortName);

		File.makeDirectory(dir+ShortName);

		//Open .lif//

		run("Bio-Formats Importer", "open=["+path+"] color_mode=Default view=Hyperstack stack_order=XYCZT use_virtual_stack open_all_series ");

		//Saving as .tif the content of the .lif files, in their destination folders//

		list = getList("image.titles");

		//get the name of each image opened//  

		ids=newArray(nImages);

		for (j=0; j<list.length; j++){

			//print(list[j]);

			selectImage(j+1);

			ids[j]=getTitle;

			//Get experiment name (title of the .lif file)//

			experiment_name=substring(ids[j],0,indexOf(ids[j],".lif"));

			//Remove the name of the .lif file that is included in each image//

			short_name1 = substring(ids[j], indexOf(ids[j], "- "), lastIndexOf(ids[j], ""));

			short_name = replace(short_name1, "- ", "");

			//If not a stack, save directly as .tif with a short name//

			if (nSlices==1){				

				print("Not a stack");

				run("8-bit");

				saveAs("Tiff", dir+File.separator+experiment_name+File.separator+short_name);

				print(short_name, ">>> Image saved as .tif");			

			//If a stack, reverse and save as .tif with a short name//

			} else {

				run("Reverse");

				run("8-bit");

				saveAs("Tiff", dir+File.separator+experiment_name+File.separator+short_name);

				print("----- ",short_name, " >>> Reversed and saved as .tif");

				};

			getPixelSize(unit, pw, ph, pd);

			print("Voxelsize="+pw+"x"+ph+"x"+pd+" "+unit+"^3");

			print("nSlices="+nSlices);

			};

		run("Close All");

		print("Done with", FileName,"!");

	} else {

	print("### ",FileName," Not a .lif file###");

	};

};	

print("Done with this folder!!!");